Программное создание динамического списка на управляемой форме. (Динамическое создание динамического списка). Готовая процедура + обработка - демонстрационный пример

Публикация № 728597

Разработка - Практика программирования

Динамический список программное создание элементов элементы формы управляемая форма

269
Если у вас возникает необходимость на форму влиять динамически и создавать элементы управляемой формы программно, а особенно хотите вывести программно (динамически) динамический список, вам будет интересна эта процедура. Процедура включает также возможность формирования своей командной панели (а-ля снятие галочки "Автозаполнение" у стандартной командной панели списка).

https://awards.infostart.ru/img/3.png

https://awards.infostart.ru/img/infostartawards.png 2018

Добрый день, Коллеги!

Возникла необходимость в программном создании элементов формы, особенно такого как динамический список. Необходимо программно влиять на него полностью, включая и формирование необходимых мне колонок. Данная процедура может выполняться за сеанс формы N-ное количество раз, поэтому и была написана универсальная процедура формирования динамического списка:

&НаСервере
Процедура СозданиеДинамическогоСписка(
	ИмяСписка = "Список", 			//тип строка - имя будущего списка на форме и реквизита
	ТекстЗапроса = "", 				//тип строка - запрос, если он не указан, необходимо указать таблицу
	МассивКолонок,                  //тип массив - массив создаваемых колонок, значения тип строка. Пример: "Д,ДоговораКонтрагента" значит будет создана колонка
									//				с заголовком "Д" и колонкой списка "ДоговораКонтрагента". Если указать просто "ДоговораКонтрагента", 
									//				заголовок будет идентичен заголовку по умолчанию типа "Договор контрагента".
	СписокДействий = Неопределено,  //типа структура - структура содержит действия (свойства) динамического списка, можно указать только те которые необходимы.
									//				пример: СписокДействий = Новый Структура("Выбор,ПриАктивизацииСтроки","СписокВыбор","СписокПриАктивизацииСтроки")
	ТаблицаСписка = "",				//тип строка - содержит имя основной таблицы, пример: "Документ.РеализацияТоваровУслуг"	
	ДобавитьВ = "",                 //тип строка - имя элемента на который будет размещен список, если пустое, тогда добавляется на форму
	ВставитьПеред = "",             //тип строка - имя элемента перед которым будет размещен список, если пустое, будет просто добавлен в конец
	СвояКоманднаяПанель = ЛОЖЬ,     //тип булево - если ИСТИНА, скрывает стандартную панель и создает свою пустую для будушего наполнения ИмяСписка+"КоманднаяПанель2"
	ПараметрыЗапроса = Неопределено)//тип структура - содержит перечень параметров, если они используются в запросе.
	
	//Защита от дурака
	Если ТекстЗапроса = "" И ТаблицаСписка = "" Тогда Сообщить("Ошибка формирования динамического списка, укажите запрос или таблицу"); Возврат; КонецЕсли;
																									
	//Создаем свою командную панель, тот случай когда я не нашел способа снять галочку "Автозаполнение"
	Если СвояКоманднаяПанель Тогда
		Если ВставитьПеред = "" Тогда
			ГруппаДинамическогоСписка  = Элементы.Добавить("Группа" + ИмяСписка + "CоСвоейКоманднойПанелью",Тип("ГруппаФормы"),?(ДобавитьВ = "",ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]));
		Иначе
			ГруппаДинамическогоСписка  = Элементы.Вставить("Группа" + ИмяСписка + "CоСвоейКоманднойПанелью",Тип("ГруппаФормы"),?(ДобавитьВ = "",ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]),ЭтаФорма.Элементы[ВставитьПеред]);			
		КонецЕсли;
		ГруппаДинамическогоСписка.Вид = ВидГруппыФормы.ОбычнаяГруппа;
		ГруппаДинамическогоСписка.ОтображатьЗаголовок = Ложь;
		ГруппаДинамическогоСписка.Отображение = ОтображениеОбычнойГруппы.Нет;
		ГруппаДинамическогоСписка.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Вертикальная;
		КоманднаяПанельСписка  = Элементы.Добавить(ИмяСписка + "КоманднаяПанель2",Тип("ГруппаФормы"),ГруппаДинамическогоСписка);
		КоманднаяПанельСписка.Вид = ВидГруппыФормы.КоманднаяПанель;			
	КонецЕсли;
									
	//Создаем реквизит формы
	ТипыРеквизита = Новый Массив;                             
	ТипыРеквизита.Добавить(Тип("ДинамическийСписок"));
	ОписаниеТиповДляРеквизита = Новый ОписаниеТипов(ТипыРеквизита); 
	ДинамическийСписок = Новый РеквизитФормы(ИмяСписка, ОписаниеТиповДляРеквизита,,"",ЛОЖЬ); //Имя реквизита
	ДобавляемыеРеквизиты = Новый Массив;
	ДобавляемыеРеквизиты.Добавить(ДинамическийСписок);        
	
	//Задаем свойства реквизиту
	ИзменитьРеквизиты(ДобавляемыеРеквизиты);        
	РеквизитДинамическийСписок = ЭтаФорма[ИмяСписка]; //Имя реквизита
	Если ТекстЗапроса = "" Тогда
		РеквизитДинамическийСписок.ПроизвольныйЗапрос = ЛОЖЬ;
		РеквизитДинамическийСписок.ОсновнаяТаблица = ТаблицаСписка;
	Иначе
		РеквизитДинамическийСписок.ПроизвольныйЗапрос = ИСТИНА;
		РеквизитДинамическийСписок.ТекстЗапроса = ТекстЗапроса;
		Если ТаблицаСписка <> "" Тогда РеквизитДинамическийСписок.ОсновнаяТаблица = ТаблицаСписка; КонецЕсли;		
	КонецЕсли;
	
	//Заполняем параметры если они были указаны
	Если ПараметрыЗапроса <> Неопределено Тогда
		Для Каждого Параметра из ПараметрыЗапроса Цикл
			РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра(Параметра.Ключ,Параметра.Значение);	
		КонецЦикла;		 
	КонецЕсли;
	
	//Размещаем реквизит на форме
	Если ЛОЖЬ
		ИЛИ ВставитьПеред = "" 
		ИЛИ СвояКоманднаяПанель //Если своя командная панель тогда нет логики уже в параметре ВставитьПеред
		Тогда
		ТаблицаФормы = Элементы.Добавить(ИмяСписка,Тип("ТаблицаФормы"),?(СвояКоманднаяПанель,ГруппаДинамическогоСписка,?(ДобавитьВ = "",ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ])));
	Иначе
		ТаблицаФормы = Элементы.Вставить(ИмяСписка,Тип("ТаблицаФормы"),?(ДобавитьВ = "",ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]),ЭтаФорма.Элементы[ВставитьПеред]);	
	КонецЕсли;		
	ТаблицаФормы.ПутьКДанным = ИмяСписка; //Имя реквизита 
	
	//Если своя панель тогда скрываем стандартную
	Если СвояКоманднаяПанель Тогда
		Элементы[ИмяСписка].ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет;
	КонецЕсли;

	//Создание колонок на основание МассивКолонок
	Для Каждого Элемента Из МассивКолонок Цикл
		ПараметрыКолонки = СтрЗаменить(Элемента,",",Символы.ПС);
		Если СтрЧислоСтрок(ПараметрыКолонки) > 1 Тогда
			Заголовок = СтрПолучитьСтроку(ПараметрыКолонки, 1);
			ИмяКолонки = СтрПолучитьСтроку(ПараметрыКолонки, 2);
		Иначе
			Заголовок = "";
			ИмяКолонки = ПараметрыКолонки; 
		КонецЕсли;	
		НоваяКолонкаТаблицы = Элементы.Добавить(ИмяСписка + ИмяКолонки, Тип("ПолеФормы"), ТаблицаФормы);
		Если Заголовок <> "" Тогда НоваяКолонкаТаблицы.Заголовок = Заголовок; КонецЕсли;
		НоваяКолонкаТаблицы.ПутьКДанным = ИмяСписка + "." + ИмяКолонки; 	
	КонецЦикла;
	
	//Задаем действия (События) на основание СписокДействий, если он определен
	Если СписокДействий <> Неопределено Тогда 	
		ПереченьСвойств = "ПриИзменении
						|Выбор
						|ПриАктивизацииСтроки
						|ВыборЗначения
						|ПриАктивизацииПоля
						|ПриАктивизацииЯчейки
						|ПередНачаломДобавления
						|ПередНачаломИзменения
						|ПередУдалением
						|ПриНачалеРедактирования
						|ПередОкончаниемРедактирования
						|ПриОкончанииРедактирования
						|ОбработкаВыбора
						|ПередРазворачиванием
						|ПередСворачиванием
						|ПослеУдаления
						|ПриСменеТекущегоРодителя
						|ОбработкаЗаписиНового
						|ПриСохраненииПользовательскихНастроекНаСервере
						|ПередЗагрузкойПользовательскихНастроекНаСервере
						|ПриЗагрузкеПользовательскихНастроекНаСервере
						|ПриОбновленииСоставаПользовательскихНастроекНаСервере
						|ОбработкаЗапросаОбновления
						|ПриПолученииДанныхНаСервере
						|НачалоПеретаскивания
						|ПроверкаПеретаскивания
						|ОкончаниеПеретаскивания
						|Перетаскивание";
		Для Счетчик = 1 по 28 Цикл
			ИмяСвойства = СтрПолучитьСтроку(ПереченьСвойств, Счетчик);
			Элементы[ИмяСписка].УстановитьДействие(ИмяСвойства,?(СписокДействий.Свойство(ИмяСвойства),СписокДействий[ИмяСвойства],""));
		КонецЦикла;
	КонецЕсли;	

КонецПроцедуры 
 
 
Процедура на момент публикации 19.01.18 10:59

Но если мы что-то создаем программно, то должны уметь и удалять это программно. Поэтому вытекающая процедура это удаление списка:

&НаСервере
Процедура УдалениеДинамическогоСписка(ИмяСписка);	
	
	Если ЭтаФорма.Элементы.Найти(ИмяСписка) <> Неопределено Тогда
		//Удаляем реквизиты формы
	    МассивУдаляемыхРеквизитов = Новый Массив;
		МассивУдаляемыхРеквизитов.Добавить(ИмяСписка);
		ИзменитьРеквизиты(,МассивУдаляемыхРеквизитов); 	
		
		//Удаляем эелементы формы
		Элементы.Удалить(Элементы[ИмяСписка]);	
	КонецЕсли;
	
	//Удаляем командную панель свою, если есть
	Если Элементы.Найти(ИмяСписка + "КоманднаяПанель2") <> Неопределено Тогда
		Элементы.Удалить(Элементы[ИмяСписка + "КоманднаяПанель2"]);
	КонецЕсли;
	
	//Удаляем группу созданую при условие если нужна своя командная панель
	Если Элементы.Найти("Группа" + ИмяСписка + "CоСвоейКоманднойПанелью") <> Неопределено Тогда
		Элементы.Удалить(Элементы["Группа" + ИмяСписка + "CоСвоейКоманднойПанелью"]);		
	КонецЕсли;

КонецПроцедуры 

Но не стоит забывать, что просто создать на форме элемент динамического списка - зачастую мало, пример постобработки программно созданного динамического списка демонстрирую ниже.

 

Пример использования (простой):

 


Пример использования (сложный):

Демонстрация работы показана на 1С:Комплексная автоматизация 2 (УТ11, ERP), но так же будет работать и в режиме мистической совместимости 8.2.13 (1С:Комплексная автоматизация 1.1), так как именно для старой доброй 1.1 и делалось и используется. Для простоты восприятия пример использования представлен на видео (без озвучки правда), сама обработка прилагается к публикации.

Как видно, в обработке программно (динамически) формируется динамический список на форме в зависимости от смены имени метаданных документа. Если углубиться, то динамически формируется в обработке также и список будущих колонок по наличию реквизитов у документа, а также сама выборка - текст запроса. Ниже демонстрирую, для чего всё это было, упрощение будущего сопровождения при расширение списка документов:

 

Пример из практики - история разработки этой процедуры

Есть некая разработка регистрации первичных документов. Управление производится через АРМы. Если в начале жизни разработки, АРМ был рассчитан всего на три документа, то мне было несложно разместить все элементы и описать логику их работы. Но время идёт и хотелки растут, вот уже документов стало пять... А потом попросили ещё пять добавить. И я чувствую, это их (бухгалтерию) не остановит. Тут я и понял, что дальнейшее сопровождение АРМа просто мучительно для меня. Переосмысление привело к разработке с нуля, не помню, кто сказал, но перефразирую: "Когда ты чувствуешь что обрастаешь г...внокодом - остановись и начни с нуля". Так и сделал.

Благодаря новой логике, дальнейшее расширение АРМа количеством документов делается просто - добавляются необходимые значения в перечисление ТипДокумента и без кодинга уже будет работать АРМ.

Визуально для конечного пользователя на форме ничего не изменилось за исключением исчезновения "страниц" и появления переключателя "ТипДокумента". Но с технической стороны, изменения колоссальные:

 

А теперь о неприятном!

При программном создании динамического списка естественно появляется желание программно влиять на весь элемент формы, а именно речь пойдёт о трудностях с командной панелью и контекстным меню. Программно я не нашел способа добраться до свойства "Автозаполнение":

Казалось бы, почему бы не обратиться просто... Элементы[ИмяЭлемента]КоманднаяПанель.Автозаполнение = ЛОЖЬ, но нет такого свойства. Поэтому пришлось применять хитрости (костыли).

 

Командная панель.

Вопрос с командной панелью решил в процедуре публикации следующим образом:

1. Создается программно элемент группа, вид обычная группа, группировка - горизонтальная, отображать заголовок - ложь.

2. Создается программно в выше созданной группе элемент группа с видом командная панель. Именно она теперь будет основной командной панелью будущего динамического списка.

3. Добавляется создаваемый программно элемент таблица формы (динамический список).

4. У таблицы формы отключается вывод командной панели.

 

Контекстное меню.

Вопрос по отключению "Автозаполнения" в контекстном меню - решения не нашел. Подозреваю, что это невозможно технически.

 

Удачного кодинга!

 

269

Скачать файлы

Наименование Файл Версия Размер
Демонстрационный пример работы процедуры и её использования (обработка которая показана в видео)
.epf 9,96Kb
22.03.19
55
.epf 1.0.0.1 9,96Kb 55 Скачать

Специальные предложения

Лучшие комментарии
14. rpgshnik 1683 26.01.18 05:26 Сейчас в теме
(13) Можно)
Но в моём случае пришлось изменить всё таки запроса (как без изменения запроса не в курсе).
Но нужно это делать аккуратно, чтобы таблица не слетела и колонки не уехали.
Пример прилагаю, на основание таблицы Партнёры, добавил после дополнительное свойства "Экспедитор"... на демки КА 2.2 делал. Обработку прилагаю.

&НаСервере
Процедура ИзменитьЗапросНаСервере()
	ТекстЗапроса = "ВЫБРАТЬ
	               |	Партнеры.Наименование КАК Наименование,
	               |	Партнеры.Клиент КАК Клиент,
	               |	Партнеры.ОсновнойМенеджер КАК ОсновнойМенеджер,
	               |	Партнеры.Комментарий КАК Комментарий,
	               |	ЕСТЬNULL(ВложенныйЗапрос.Значение, """") КАК Экспедитор,
	               |	Партнеры.Ссылка
	               |ИЗ
	               |	Справочник.Партнеры КАК Партнеры
	               |		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	               |			ПартнерыДополнительныеРеквизиты.Ссылка КАК Ссылка,
	               |			ПартнерыДополнительныеРеквизиты.Свойство КАК Свойство,
	               |			ПартнерыДополнительныеРеквизиты.Значение КАК Значение
	               |		ИЗ
	               |			Справочник.Партнеры.ДополнительныеРеквизиты КАК ПартнерыДополнительныеРеквизиты
	               |		ГДЕ
	               |			ПартнерыДополнительныеРеквизиты.Свойство.Наименование = ""Экспедитор"") КАК ВложенныйЗапрос
	               |		ПО Партнеры.Ссылка = ВложенныйЗапрос.Ссылка";
	
	дСписок.ТекстЗапроса = ТекстЗапроса;
КонецПроцедуры

&НаКлиенте
Процедура ИзменитьЗапрос(Команда)
	ИзменитьЗапросНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДобавитьКолонкиПослеИзмененияЗапросаНаСервере()
	НоваяКолонкаТаблицы = Элементы.Вставить("Экспедитор",Тип("ПолеФормы"),Элементы.дСписок,Элементы.дСписокКомментарий);
	НоваяКолонкаТаблицы.ПутьКДанным = "дСписок.Экспедитор"; 
КонецПроцедуры

&НаКлиенте
Процедура ДобавитьКолонкиПослеИзмененияЗапроса(Команда)
	ДобавитьКолонкиПослеИзмененияЗапросаНаСервере();
КонецПроцедуры
Показать


Если конфигурация на замке - можно с расширениями попробовать.
Прикрепленные файлы:
котКакВывестиДополнительныеСвойства.epf
Остальные комментарии
Избранное Подписка Сортировка: Древо
1. palsergeich 19.01.18 13:14 Сейчас в теме
Код приятный.
Нужно только понимать, после ПриСозданииНаСервере добавление\удаление реквизитов - очень дорогая операция...
vovan_victory; rpgshnik; +2 Ответить
2. rpgshnik 1683 19.01.18 14:04 Сейчас в теме
(1) спасибо, учту про стоимость операции.
3. pm74 132 19.01.18 18:15 Сейчас в теме
(0) полезная публикация , спасибо
rpgshnik; +1 Ответить
4. Denis Nsk 21.01.18 16:36 Сейчас в теме
Спасибо большое!
Лично для меня, очень полезная публикация. Отметил в избранное на будущее.
Спасибо за потраченное время и подробное описание!
rpgshnik; +1 Ответить
5. Batchir 126 24.01.18 11:28 Сейчас в теме
Спасибо!
Появились хотелки к статье)))
1. Не хватает в статье описания того, как в таком случае устанавливать параметры динамического списка.
В "типовом" варианте это делается на сервере:
МойСписок.Параметры.УстановитьЗначениеПараметра("МойПараметр",ЗначениеМоегоПараметра);
При программном создании "МойСписок" отсутствует и будет валиться на синтаксис.
2. Было бы замечательно если бы описали формирование колонок динамического списка.
Причем с возможностью указания группировок колонок. Не всегда нужно сформировать линейный динамический список.
rpgshnik; +1 Ответить
6. rpgshnik 1683 24.01.18 12:53 Сейчас в теме
(5) Дельные хотелки, когда есть обратная связь особенно интересно.

1. Как-то я забыл про Параметры, у меня их не было, я как-то отборами привык уже))
Добавлю в саму процедуру, обновлю чуть позже.

2. Я конечно не хотел преследовать супер-универсальности, возможно подумаю, но не обещаю.
Да и цель была именно линейные списки. Возможно стоит проще постобработкой список скорректировать группировками... я и отборы не добавляю, так это точно перебор)))
9. rpgshnik 1683 25.01.18 05:54 Сейчас в теме
(5) функционал в процедуру по передачи параметров добавил, публикацию обновил.
	//Заполняем параметры если они были указаны
	Если ПараметрыЗапроса <> Неопределено Тогда
		Для Каждого Параметра из ПараметрыЗапроса Цикл
			РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра(Параметра.Ключ,Параметра.Значение);	
		КонецЦикла;		 
	КонецЕсли;


на второй ваше предложение, используйте группировки, ни их не отборы в процедуру добавлять не планирую
11. Batchir 126 25.01.18 10:13 Сейчас в теме
(9) Да я то что ))) Если мне нужно будет, то конечно буду использовать (и сам смогу дописать). Это хотелка была для полноты статьи: программное создание, размещение динамического списка есть, а программного управления колонками нет (размещение в группах вместе, горизонтально ...).
В любом случае ещё раз спасибо. Саму функцию закинул в шаблоны, думаю пригодиться.
rpgshnik; +1 Ответить
12. rpgshnik 1683 25.01.18 10:42 Сейчас в теме
7. Vlad_2008 12 24.01.18 13:04 Сейчас в теме
Ну синтаксис можно и обойти: ЭтаФорма["МойСписок"].Установить ...

А вот как быть с характеристиками (а-ля "доп. реквизиты" в типовых)? Их можно задать в конфигураторе в свойствах объекта, тут получается что надо все вставлять в запрос для каждой формы объекта.

И, может кто-нибудь знает, как программно добавить колонку с характеристикой, как будто пользователь вынес на форму поле Ссылка.[Мой доп реквизит] ? В запросе-то поля нет, а вот в "Изменить форму - Ссылка - Добавить поля" - есть.
8. rpgshnik 1683 25.01.18 04:44 Сейчас в теме
(7) интересно, но не сталкивался( вообще мало работаю с новыми конфигами, увяз в совместимости 8.2.13
10. rpgshnik 1683 25.01.18 06:19 Сейчас в теме
(7) Мне кажется я понял вас. Я почему-то подумал про ПВХ и дополнительные Свойства Объектов.
А вы говорите просто об реквизитах ссылочного объекта.
Тогда программно практически так же как в моей процедуре, за исключением указания пути к данным, как к объектной модели.

Пример, запрос динамического списка:
ВЫБРАТЬ
	РеализацияТоваровУслуг.Дата,
	РеализацияТоваровУслуг.Номер,
	РеализацияТоваровУслуг.Организация,
	РеализацияТоваровУслуг.Контрагент
ИЗ
	Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг


Код обработки события, к примеру по нажатию кнопки:
&НаКлиенте
Процедура ДобавитьКолонку(Команда)
	ДобавитьКолонки();
КонецПроцедуры

&НаСервере
Процедура ДобавитьКолонки()
	НоваяКолонкаТаблицы = Элементы.Вставить("дСписокКонтрагентИНН",Тип("ПолеФормы"),Элементы.дСписок,Элементы.дСписокОрганизация);
	НоваяКолонкаТаблицы.ПутьКДанным = "дСписок.Контрагент.ИНН"; 
	НоваяКолонкаТаблицы.Заголовок = "ИНН";
	НоваяКолонкаТаблицы = Элементы.Вставить("дСписокКонтрагентКПП",Тип("ПолеФормы"),Элементы.дСписок,Элементы.дСписокОрганизация);
	НоваяКолонкаТаблицы.ПутьКДанным = "дСписок.Контрагент.КПП"; 
	НоваяКолонкаТаблицы.Заголовок = "КПП";
	НоваяКолонкаТаблицы = Элементы.Добавить("дСписокОрганизацияИНН",Тип("ПолеФормы"),Элементы.дСписок);
	НоваяКолонкаТаблицы.ПутьКДанным = "дСписок.Организация.ИНН"; 
	НоваяКолонкаТаблицы.Заголовок = "ИНН";
КонецПроцедуры
Показать


Обработка прилагается:
Прикрепленные файлы:
котКакДобавитьКолонкуПрограммноВместоИзменитьФорму.epf
13. Vlad_2008 12 25.01.18 17:43 Сейчас в теме
(10)
Не, я как раз именно про ПВХ. С реквизитами все понятно и просто. А вот как с характеристиками - вопрос?

В отчете на СКД я могу добавить поле программно (например в отбор) так:
Новый ПолеКомпоновкиДанных("Организация.[Связанный контрагент]");

Дин. список тоже на СКД, характеристики можно описать в свойствах объекта или в конструкторе запроса.
Ес-но, можно программно задать текст запроса с характеристиками, после чего пользователь сможет вынести на форму колонку с произвольной характеристикой.

Так вот и не могу понять можем ли мы программно создать такую колонку? Как указать путь к данным?
14. rpgshnik 1683 26.01.18 05:26 Сейчас в теме
(13) Можно)
Но в моём случае пришлось изменить всё таки запроса (как без изменения запроса не в курсе).
Но нужно это делать аккуратно, чтобы таблица не слетела и колонки не уехали.
Пример прилагаю, на основание таблицы Партнёры, добавил после дополнительное свойства "Экспедитор"... на демки КА 2.2 делал. Обработку прилагаю.

&НаСервере
Процедура ИзменитьЗапросНаСервере()
	ТекстЗапроса = "ВЫБРАТЬ
	               |	Партнеры.Наименование КАК Наименование,
	               |	Партнеры.Клиент КАК Клиент,
	               |	Партнеры.ОсновнойМенеджер КАК ОсновнойМенеджер,
	               |	Партнеры.Комментарий КАК Комментарий,
	               |	ЕСТЬNULL(ВложенныйЗапрос.Значение, """") КАК Экспедитор,
	               |	Партнеры.Ссылка
	               |ИЗ
	               |	Справочник.Партнеры КАК Партнеры
	               |		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	               |			ПартнерыДополнительныеРеквизиты.Ссылка КАК Ссылка,
	               |			ПартнерыДополнительныеРеквизиты.Свойство КАК Свойство,
	               |			ПартнерыДополнительныеРеквизиты.Значение КАК Значение
	               |		ИЗ
	               |			Справочник.Партнеры.ДополнительныеРеквизиты КАК ПартнерыДополнительныеРеквизиты
	               |		ГДЕ
	               |			ПартнерыДополнительныеРеквизиты.Свойство.Наименование = ""Экспедитор"") КАК ВложенныйЗапрос
	               |		ПО Партнеры.Ссылка = ВложенныйЗапрос.Ссылка";
	
	дСписок.ТекстЗапроса = ТекстЗапроса;
КонецПроцедуры

&НаКлиенте
Процедура ИзменитьЗапрос(Команда)
	ИзменитьЗапросНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДобавитьКолонкиПослеИзмененияЗапросаНаСервере()
	НоваяКолонкаТаблицы = Элементы.Вставить("Экспедитор",Тип("ПолеФормы"),Элементы.дСписок,Элементы.дСписокКомментарий);
	НоваяКолонкаТаблицы.ПутьКДанным = "дСписок.Экспедитор"; 
КонецПроцедуры

&НаКлиенте
Процедура ДобавитьКолонкиПослеИзмененияЗапроса(Команда)
	ДобавитьКолонкиПослеИзмененияЗапросаНаСервере();
КонецПроцедуры
Показать


Если конфигурация на замке - можно с расширениями попробовать.
Прикрепленные файлы:
котКакВывестиДополнительныеСвойства.epf
20. Vida 11 13.12.18 11:07 Сейчас в теме
(14) В отличие от автора статьи, у вас есть реквизит дСписок - динамический список. Поэтому в указанных вводных ваш код работать не будет, а именно

дСписок.ТекстЗапроса = ТекстЗапроса;

по причине из (5) часть 1

А вот как это обойти - не придумала.
21. Vida 11 13.12.18 18:16 Сейчас в теме
(14) Так вы и есть автор! Нашла свою ошибку почему не могла параметры поменять. Создаю программно "СписокМой", а потом пытаюсь изменить параметры у "МойСписок".

Все отлично работает
&НаСервере
Процедура СписокПриАктивизацииСтрокиНаСервере(ДатаР, НомерР, ИмяСписка)
	Если ЭтаФорма.Элементы.Найти(ИмяСписка) <> Неопределено Тогда
		РеквизитДинамическийСписок = ЭтаФорма[ИмяСписка]; 
		РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра("НомерРег", НомерР);
		РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра("ДатаРег", ДатаР);
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура СписокПриАктивизацииСтроки(Элемент)
	Сообщить(Элемент.ТекущиеДанные.Дата);
	СписокПриАктивизацииСтрокиНаСервере(Элемент.ТекущиеДанные.Дата, Элемент.ТекущиеДанные.Номер, "СписокМой");
КонецПроцедуры
Показать
15. antont 12 03.07.18 11:41 Сейчас в теме
(13) Можно и без изменения запроса.
В качестве пути к данным указывается имя доступного поля выбора компоновщика настроек динамического списка.

ЕМаил = Элементы.Добавить("ЕМаил",Тип("ПолеФормы"),Элементы.Список);
	ЕМаил.ПутьКДанным ="Список.Ссылка.[E-mail]";
16. Vlad_2008 12 03.07.18 16:26 Сейчас в теме
(15)
Работает, спасибо!

Основная проблема была в том, что невозможно было определить колонку, которую пользователь добавил через "Изменить форму" ... ну я никак не смог до нее достучаться ... в элементах формы ее тоже нет.

С добавленной программно колонкой все хорошо, вот только в настройках формы она "автоматом" не сохраняется, но это уже другая история ...
17. t0202 9 17.08.18 10:11 Сейчас в теме
Спасибо, успешно воспользовался Вашей процедурой.

Заметил один недостаток.

В массиве колонок желательно поменять местами заголовок и имя колонки.
У меня заголовки колонок оказались с запятыми и пришлось это поправить.
rpgshnik; +1 Ответить
18. rpgshnik 1683 17.08.18 10:59 Сейчас в теме
19. Daynestro07 07.11.18 15:12 Сейчас в теме
Дельная статья. Интересно только, есть ли способ получить массив выводимых колонок автоматически, из запроса?

upd Уже неактуально
rpgshnik; +1 Ответить
22. mikl79 107 19.12.18 15:38 Сейчас в теме
Большое спасибо автору!!!
Очень нужная Процедура - воспользовался, применил в расширении, вообще стараюсь программно в расширении добавлять на форму реквизиты, табл.части, кнопки, теперь и динам.список смогу.
Единственное, мне нужно вывести динам.список на отдельную страницу.
rpgshnik; +1 Ответить
23. mikl79 107 19.12.18 16:21 Сейчас в теме
немного доработал Процедуру - добавил еще один параметр, чтобы выводилось на страницу
24. rpgshnik 1683 20.12.18 03:45 Сейчас в теме
(23) не смог понять, а параметра - "ДобавитьВ" не достаточно? Интересно.
25. mikl79 107 20.12.18 11:27 Сейчас в теме
(24), действительно воспользовался параметром "ДобавитьВ", но перед вызовом процедуры программно создал новую страницу
rpgshnik; +1 Ответить
26. mikl79 107 20.12.18 11:53 Сейчас в теме
Не сразу заметил, что вы используете при добавлении элементов на форму процедуры Добавить и Вставить, в чем их разница - не понял.
"Вставить" в отличие от "Добавить" только содержит 4-й параметр "Элемент" - Элемент, перед которым должен быть вставлен новый элемент. Если не указан, то элемент будет вставлен в конец.
А так вроде делают одно и тоже, но это наверное вопрос риторический - разработчикам.
rpgshnik; +1 Ответить
Оставьте свое сообщение

См. также

Генерация QR кода для любых конфигураций 1С (обычные и управляемые формы) 4

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Универсальные обработки Универсальные функции

Для генерации используется компонента типовой конфигурации УТ11, встроенная в общий макет "КомпонентаПечатиQRКода". Ниже приведены процедуры, чтобы сделать обработку самостоятельно (только для УФ).

1 стартмани

11.10.2019    520    3    dm1try    0       

Индикатор выполнения (прогресс-бар) с таймером остаточного времени выполнения (обычное приложение + УФ) 1

Отчеты и формы Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Работа с интерфейсом

Индикатор (прогресс-бар) - элемент формы, отображающий ход выполнения операций по счетчику. В данном решении разработана возможность отслеживания остаточного времени выполнения.

1 стартмани

08.10.2019    424    1    slayer-ekb    5       

Описание формата внутреннего представления данных 1С в контексте обмена данными 143

Статья Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных Разработка

Фирма 1С не рекомендует использовать внутреннее представление данных для любых целей, которые отличны от обмена с 1С:Предприятием 7.7. Но сама возможность заглянуть на "внутреннюю кухню" платформы с помощью функций ЗначениеВСтрокуВнутр(), ЗначениеВФайл(), ЗначениеИзСтрокиВнутр() и ЗначениеИзФайла(), дала возможность сообществу программистов 1С разработать новые приемы разработки и анализа. Так, именно на использовании внутреннего представления был построен алгоритм "быстрого массива", который позволяет практически мгновенно создать массив в памяти на основании строки с разделителями. С помощью разбора внутреннего представления можно "на лету" программным кодом выполнить анализ обычной формы и даже сделать редактор графической схемы. Во внутреннем формате сохраняют свои данные между сеансами различные популярные внешние обработки. А еще это возможность сделать быстрый обмен с внешними системами.

1 стартмани

06.09.2019    4241    4    Dementor    27       

Обновление данных в ячейках таблицы формы на управляемых формах 9

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

На очередном проекте решал задачу по расчету значений колонок в табличных полях формы. Задача казалась достаточно простой. Однако возникла необходимость работать не только с реквизитами формы типа «ТаблицаЗначений», но и с типом «ДеревоЗначений». Релиз платформы 8.3.13.1644

1 стартмани

15.08.2019    943    BraunAlex    2       

Удобный выбор из таблицы/дерева в УФ 61

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Работа с интерфейсом Разработка

Выбор из таблицы значений или дерева значений в выпадающем списке рядом с полем ввода - УФ, быстро и просто!

1 стартмани

12.08.2019    2881    4    Yashazz    18       

Отбор на управляемой форме из списка значений 41

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Работа с интерфейсом Разработка

Пример простого удобного отбора любых данных ссылочного типа на управляемой форме. Работа обработки проверена на релизе: 1С:Предприятие 8.3.13.1513.

1 стартмани

09.08.2019    4187    4    nagaitseff    6       

Организация функционала наценок по позициям либо сегментам номенклатуры в УТ 11.4 5

Статья Программист Документ XML v8::ОУ v8::УФ УТ11 Россия УУ Ценообразование, анализ цен Абонемент ($m) Практика программирования Разработка

В статье описан один из методов реализации задачи установки скидок/наценок в соответствии с заданным процентом по позициям/сегментам номенклатуры. Так-же продемонстрирован принцип создания произвольного запроса к ИБ в виде цен. Протестировано на релизе Управление торговлей, редакция 11.4.8.92.

1 стартмани

07.08.2019    883    cheiser1982    2       

Изменяющееся контекстное меню в 1С 8.3 44

Статья Программист Архив с данными v8 v8::УФ Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

В одной практической задаче мне пришлось разрабатывать контекстное меню таблицы управляемой формы, которое должно было меняться в зависимости от данных, находящихся в этой таблице. Ниже приведен мой способ решения этой задачи.

1 стартмани

06.08.2019    4227    1    signum2009    14       

Запрет запуска более одного сеанса на рабочем месте (Розница 2.2) 6

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ Розница Россия Абонемент ($m) Практика программирования Разработка

Доброго времени! Столкнулся с проблемой - при запуске более одного сеанса конфигурации "Розница 2.2" на одном рабочем месте возникают конфликты с подключенным оборудованием. Пришлось в быстром темпе это исправить - запретом повторных запусков. Также, кому интересно, можно посмотреть, как обращаюсь из модуля управляемого приложения к серверным процедурам (описание примера).

2 стартмани

04.08.2019    1135    aximo    5       

Универсальная печать штрихкодов Windows, Linux, x86, x64. Управляемые формы. Веб-клиент. Пример 3

Инструменты и обработки Программист Стажер Конфигурация (md, cf) v8::УФ 1cv8.cf ОС Абонемент ($m) Разработка внешних компонент Практика программирования

Универсальная печать штрихкодов Windows, Linux, x86, x64. Управляемые формы. Веб-клиент. Сделана на основе компонент печати штрихкодов фирмы 1с под платформу 1с windows32, windowsx64, linux32, linux64. Типы штрихкодов для генерации - EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5. Сделана как пример для внедрения. Наиболее оптимальный вариант для веб-клиента. Пример сделан в виде cf файла. Работоспособность проверялась на ERP 2.4.8.84, ЗУП 3.1.9.187, Розница 2.2.11.30, УНФ 1.6.17.128, БГУ 2.0.61.28, ЗКГУ 3.1.9.187, КА 2.4.7.127, УТ 11.4.7.128, БП 3.0.69.35, Документооборот КОРП ПРОФ 2.1.13.28.

1 стартмани

17.07.2019    1300    4    ivanchai    0       

Вам нравятся запросы в 1С? 13

Инструменты и обработки Программист Конфигурация (md, cf) v8 v8::Запросы 1cv8.cf Абонемент ($m) Практика программирования Разработка

Речь не только о том, что простейший запрос с "легальным" оформлением растянется на пол-экрана, речь еще обо всем, что нужно написать "в нагрузку" к тексту запроса. Все эти "Новый Запрос", "УстановитьПараметр" и последующие пляски с обработкой результата... Пора с этим заканчивать!

1 стартмани

03.07.2019    8976    1    m-rv    73       

Генерация QR кодов через API Google (обычные и управляемые формы) 4

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Инструментарий разработчика Практика программирования Разработка WEB

Обработка абсолютно автономна, не привязана ни к версии БСП, ни к виду конфигурации. Может работать как для типовых, так и для самописных конфигураций. Содержит обычную и управляемую формы, поэтому запустится в любом режиме. Единственное, что нужно для ее работы - это подключение к интернету, так как для генерации QR кодов используется сервис Google.

1 стартмани

22.06.2019    1528    3    lisrws    5       

Несколько документов на основании одного 4

Инструменты и обработки Программист Конфигурация (md, cf) v8::УФ Абонемент ($m) Обработка документов Практика программирования

На основании одного документа создаем несколько документов с табличными частями, заполненными по некоторому алгоритму. Весь код в статье.

1 стартмани

10.06.2019    1548    mvxyz    4       

Работа с графической схемой в объектной модели DOM 40

Статья Программист Конфигурация (md, cf) v8 v8::УФ Абонемент ($m) Универсальные функции

Пример кода для работы с графической схемой в объектной модели DOM, платформа 8.3.12.

1 стартмани

04.06.2019    3368    4    botokash    19       

Индикатор выполнения длительных операций на сервере 1С 8.3 (управляемые формы) 6

Инструменты и обработки Программист Архив с данными v8::УФ Россия Windows Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

Индикатор выполнения (отображение прогресса) длительных операций в тонком клиенте 1С:Предприятия 8.3, когда полностью весь код исполняется на сервере, а клиент просто ждёт завершения. Используются внешние средства (либо командное окно Windows, либо приложение Java).

1 стартмани

03.06.2019    6547    D.B.Sokolov    20       

Картинки во внешней печатной форме (Шапка и табличная часть) 9

Статья Программист Внешняя обработка (ert,epf) v8::ОУ v8::УФ УТ11 Россия Абонемент ($m) Печатные формы документов Практика программирования Разработка

Способы вывести на печать картинку в шапке и в табличной части внешней печатной формы. Управление торговлей, редакция 11 (11.4.7.150).

1 стартмани

27.05.2019    1905    2    Povinger    1       

Спутник программиста - каркасная конфигурация начинающим программистам 1С 65

Инструменты и обработки Программист Стажер Архив с данными v8::УФ 1cv8.cf Россия Windows Абонемент ($m) Практика программирования Разработка

Спутник программиста - каркасная конфигурация с примерами для разработки начинающим программистам 1С.

1 стартмани

23.05.2019    9506    95    bulas    27       

Поле "Отбор" в управляемой форме используя СКД 8

Отчеты и формы Программист Внешняя обработка (ert,epf) v8::УФ v8::СКД 1cv8.cf Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

Пример, который осуществляет отбор ссылок при помощи СКД, макет компоновки создается программно.

1 стартмани

17.05.2019    2197    2    artms    0       

Табличная часть из дополнительных реквизитов с обработкой событий в расширении 6

Статья Программист Расширение (cfe) v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

Эмуляция табличной части с помощью дополнительных реквизитов и расширения. Подход применим к любой конфигурации на управляемых формах с БСП и режимом совместимости, допускающим использование расширений. Весь код в статье.

1 стартмани

13.05.2019    2634    1    mvxyz    7       

Вывод вариантов СКД в таблицы на управляемой форме 25

Статья Программист Внешняя обработка (ert,epf) v8 v8::УФ v8::СКД 1cv8.cf Абонемент ($m) Практика программирования Работа с интерфейсом

Задача стояла такая: есть 2 различных запроса, результаты которых выгружаются на форму обработки в таблицы значений (далее ТЗ) и программно "соприкасаются" между собой определенным образом (как именно- в рамках данной статьи неважно). Нюанс в том, что запросы должны иметь свой компоновщик настроек и могут интерактивно на форме изменяться пользователем. На оригинальность публикации не претендую - изначально в рамках поставленной задачи пытался найти что-то подобное (уже готовый шаблон) на инфостарте, возможно "плохо искал" ;)

05.04.2019    3758    artkor    1       

Автоматическая генерация технологических карт на основе графической схемы 2

Инструменты и обработки Программист Архив с данными v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Практика программирования Разработка Управление бизнес-процессами (BPM)

В статье описывается способ генерация технологических карт на основе заданного графической схемой техпроцесса. Рассматриваются вопросы программного взаимодействия с объектом "графическая схема" и приведен механизм обхода графической схемы для получения карты техпроцесса. Тестировалось на платформе 8.3.12.

1 стартмани

27.03.2019    1740    all_net    0       

Безопасная работа с транзакциями во встроенном языке 183

Статья Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования Разработка

Разбираемся с опасностями использования транзакций во встроенном языке 1С. Познаем ошибку "В данной транзакции уже происходили ошибки". Учимся защищаться от них.

1 стартмани

25.03.2019    13189    7    tormozit    35       

Создание и редактирование таблиц в поле HTML документа 7

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Windows Абонемент ($m) Практика программирования Разработка

Создание и редактирование таблиц в поле HTML документа. Тестировалось на 1С:Предприятие 8.3.12.1616

1 стартмани

16.03.2019    2118    6    lastpioneer    0       

Программное создание реквизита управляемой формы с помощью механизма расширений 88

Статья Программист Расширение (cfe) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Разработка

В ЗУП 3 возникла задача добавить реквизит в справочник не внося изменений в конфигурацию. БСП с механизмом дополнительных реквизитов использовать было нежелательно, поэтому был использован механизм расширений. Для вывода данного реквизита на форму добавлять саму форму в расширение не хотелось по ряду причин, описанных ниже. Создание реквизита и элемента формы, соответствующего данному реквизиту было решено сделать программно в самом расширении, следуя принципу минимального воздействия на конфигурацию.

1 стартмани

12.03.2019    13125    8    ni_cola    24       

Робот на Клиенте (управляемое приложение), многократный запуск 2

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Разработка

Робот на Клиенте (управляемое приложение), многократный запуск. Шаблон-пример использования Обработчика Ожидания.

1 стартмани

06.03.2019    1599    Timur.V    0       

Вывод характеристик и их значений в динамический список 0

Инструменты и обработки Программист Архив с данными v8::УФ v8::СКД 1cv8.cf Абонемент ($m) Практика программирования Разработка

Если в запросе динамического списка используется конструкция {ХАРАКТЕРИСТИКИ ...}, то как вывести на форму колонки с характеристиками?

1 стартмани

22.02.2019    1895    kasper076    3       

Коннектор: удобный HTTP-клиент для 1С:Предприятие 8 509

Инструменты и обработки Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных WEB Универсальные функции Инструментарий разработчика Универсальные обработки

Коннектор - библиотека для работы с HTTP запросами. Библиотека берет на себя всю рутину работы с HTTP запросами. Буквально в одну строку можно получать данные, отправлять, не заботясь о необходимости конструирования URL, кодирования данных и т.п.

1 стартмани

31.01.2019    24902    242    bonv    102       

Использование макетов вместо дополнительных реквизитов или регистров сведений 37

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Разработка

Использование макетов вместо дополнительных реквизитов или регистров сведений на конфигурациях с БСП.

1 стартмани

27.01.2019    5573    2    Comandante    22       

Связанные табличные части (управляемые формы) 7

Инструменты и обработки Программист Конфигурация (md, cf) v8 v8::УФ Абонемент ($m) Практика программирования Разработка Работа с интерфейсом

У нас есть 2 связанные табличные части, и нам надо, чтобы по текущей строке в одной из них мы видели только определенные строки во второй. Были бы у нас динамические списки, мы бы взяли событие "При активизации строки" и стандартный механизм отборов СКД, которая лежит в основе списка. Но вот с табличными частями так не получится. Тут нам надо будет написать несколько строк кода и использовать "ОтборСтрок", доступный для таблицы формы. Тестировалось на платформе 8.3.13.1644, будет работать и на более ранних версиях платформы.

1 стартмани

25.01.2019    3541    3    Kim1C    2       

Построение градиента 3

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Работа с интерфейсом

Небольшая функция, строящая градиент, и обработка для построения произвольных градиентов.

1 стартмани

13.01.2019    2293    Serge R    1       

История реквизитов организаций (печати, факсимиле, КПП, телефон) 0

Инструменты и обработки Программист Расширение (cfe) v8::ОУ v8::УФ УТ11 Windows Абонемент ($m) Практика программирования

Решение задачи по хранению истории изменений КПП организации, дополнительных печатей, бланков и факсимиле ответственных лиц организаций, контактной информации организаций типа телефон.

1 стартмани

11.01.2019    1914    1    da_1c    0       

Быстрые параметры сеанса (решение проблемы глобальных переменных в контексте сервера) 1

Инструменты и обработки Программист Расширение (cfe) v8 v8::УФ 1cv8.cf Абонемент ($m) Универсальные функции

Расширение возможностей при адаптации, расширении и т. д. конфигураций обычного / управляемого приложения на платформе 8.3 путем предоставления доступа к так называемым быстрым параметрам сеанса в глобальном контексте (как частный случай - решение проблемы глобальных переменных в контексте сервера)

1 стартмани

22.12.2018    1859    1    Mekadote    2       

СМС2 - эрзац-мессенджер в вашей конфигурации 1С 17

Инструменты и обработки Программист Конфигурация (md, cf) v8 v8::УФ Windows Абонемент ($m) Практика программирования Работа с интерфейсом Рабочее место

Обработка предоставит вам некоторый функционал мессенджера внутри используемой конфигурации. Вложения с файлами и ссылками, аватары у пользователей, всё это можно и в 1С.

1 стартмани

17.12.2018    3738    4    semagin@gmail.com    15       

Чат на управляемых формах 9

Отчеты и формы Программист Пользователь Конфигурация (md, cf) v8 v8::УФ Абонемент ($m) Практика программирования WEB

Чат для 1С на управляемых формах, для работы в браузере. Возможности: Есть общая комната Можно создавать открытые и закрытые комнаты Переписка между двумя пользователями (беседа) Протестировано на платформе 8.3.12.1714.

2 стартмани

14.12.2018    3136    6    panihinnv    13       

ART - экспериментальный инструмент программирования 65

Инструменты и обработки Программист Архив с данными v8 v8::УФ Абонемент ($m) Практика программирования

Насколько сложным должен быть встроенный инструмент программирования для такой системы, как 1С и что получится, если упростить его до последнего предела...

1 стартмани

07.12.2018    9129    11    mkalimulin    103       

Использование подсистемы БСП "Заполнение объектов" 133

Статья Программист Расширение (cfe) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем)

Применение механизмов БСП для добавления новых команд заполнения к формам различных объектов. Использование расширений конфигурации для доработки. Шаблоны для реализации собственных команд заполнения.

1 стартмани

23.11.2018    12896    8    ids79    14       

Изображения в справке 1С 28

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования

Иногда полезно сделать скриншот и вставить его в справку. К счастью, картинку можно преобразовать в строку base64 и вставить в тег img. Выглядит это так: img src="data:image/jpg;base64,-=СТрокаИзображения=-" /img. Для редактирования можно использовать объект "форматированный документ" (реквизит формы). Данный объект может выгрузить свое содержимое в формате html и все картинки в структуру. Далее останется только преобразовать картинки в строку base64 и заменить исходные теги img.

1 стартмани

13.11.2018    4766    13    makc2k    16       

Передача набора данных типа Объект в отчет СКД 5

Инструменты и обработки Программист Внешний отчет (ert,erf) v8 v8::УФ v8::СКД 1cv8.cf Россия Абонемент ($m) Практика программирования

Пример показывает, каким образом можно передать таблицу значений в отчет СКД (в набор данных объект). Пример работает как на обычных, так и на управляемых формах.

1 стартмани

12.11.2018    13692    4    evgen7938    3       

Диаграмма Ганта и графическая схема сторонними средствами 13

Отчеты и формы Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования

Примеры формирования диаграммы Ганта и графической схемы в 1С сторонними средствами.

1 стартмани

01.11.2018    4212    3    no_betrayal    2       

Шаблон обработки с главной и подчиненной табличными частями на форме (УФ) 7

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Инструментарий разработчика Практика программирования

Организация слаженного взаимодействия главной и подчиненной табличных частей на управляемой форме - задача не из легких. Требуется учесть все возможные варианты изменения строк, которые в обеих табличных частях должны происходить согласованно. Предлагаемая обработка-шаблон позволит вам быстро и качественно организовать взаимодействие главной и подчиненной табличных частей в вашем решении.

1 стартмани

01.11.2018    2793    2    TSSV    0       

Отправка электронной почты с помощью локального почтового клиента из 1С, развернутой под удаленным рабочим столом 12

Инструменты и обработки Программист Пользователь Архив с данными v8 КА1 БП2.0 УТ10 УПП1 Windows Абонемент ($m) Печатные формы документов Универсальные функции Email

Решение для интерактивной (нажал-отредактировал) отправки электронных писем и печатных форм через почтовый клиент (Thunderbird, Outlook) находящийся на локальном компьютере, из конфигурации 1С, развернутой под удаленным рабочим столом (RDP, remote-app). Подходит также для локального развертывания 1С. Представлен пример быстрой интеграции с конфигурациями "Управление торговлей 10.3", "Управление производственным предприятием 1.3", "Комплексная автоматизация 1.1", "Бухгалтерия предприятия 2.0".

1 стартмани

21.09.2018    10999    10    stvorl    0       

Просмотр таблицы значений из файла на диске 2

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Россия Абонемент ($m) Инструментарий разработчика Практика программирования

Простая обработка, которая выводит ранее сохраненный файл с таблицей значений на форму в табличный документ. Работает как в файловом, так и в серверном варианте на управляемых формах.

1 стартмани

19.09.2018    2189    gatsubin    0       

Работа с публикациями "Инфостарт" 13

Инструменты и обработки Программист Архив с данными v8 УУ Абонемент ($m) Практика программирования О сообществе WEB

Работа с рублевыми публикациями на сайте "Инфостарт": ведение клиентов, заказов, обновление файлов публикации, рассылка обновлений.

1 стартмани

13.09.2018    8125    10    RocKeR_13    12