Паузы при исполнении кода (Sleep для 1С)

Публикация № 706204

Разработка - Практика программирования

пауза sleep

Решил проверить все найденные варианты паузы для 1С. В результате получилась обработка для тестирования и небольшая статья с итогом.

По результатам чтения форума http://forum.infostart.ru/forum9/topic42820/ и некоторых других форумов, остался вопрос: а какой вариант работает, какой лучше использовать. Для проверки была создана предлагаемая обработка. В ней можно протестировать найденные варианты. Для себя я нашел только 2 варианта: с использованием ping и winmgmts.

Более подробно про проверенные варианты:

1) ping и winmgmts. Оба варианта прекрасно работают, практически не нагружая процессор.

2) Пустой цикл. Вариант работающий, часто предлагаемый на форумах. Имеет большой минус - грузит процессор.

3) Вариант с использованием Sleep. Насколько я понимаю, требуют наличия программы sleep.exe. На моем компьютере такой нет, варианты проверить не удалось.

4) SleepJs и SleepVbs. Работают. Неплохой вариант. Варианты отличаются только алгоритмом запуска команды.

5) TimeoutWs и Timeout. Работают. Неплохой вариант. Варианты отличаются только алгоритмом запуска команды. Timeout показывает черное окно при каждом запуске паузы.

6) DynamicWrapper. Нужна dll. Этот вариант не проверял, так как искал вариант без внешних компонент.

В прилагаемой обработке все варианты можно протестировать в своей базе и выбрать наиболее подходящий.

Есть обычная и управляемая форма, поэтому запускать можно в любой базе. Код открыт.

Протестировано на версиях 8.2 и 8.3.11.

 
Процедура СделатьПаузу(ЗадержкаСекунд = 3, Вариант = "Ping")
	
    Если ЗадержкаСекунд = 0 Тогда
        Возврат
    КонецЕсли;
	
	Если ТранзакцияАктивна() Тогда
		ЗафиксироватьТранзакцию();
	КонецЕсли;
	
	Сообщить("начало: "+ТекущаяДата());
	
	Если Вариант = "Ping" Тогда
		
		СтрокаЗапроса = "ping -n 1 -w "+Формат(1000 * ЗадержкаСекунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
		WshShell = Новый COMОбъект("WScript.Shell"); 
		WshShell.Run(СтрокаЗапроса, 0, -1); 
		
	ИначеЕсли Вариант = "smaharbA" Тогда
		
		Для к = 1 По ЗадержкаСекунд Цикл
			ПолучитьCOMОбъект("winmgmts:").ExecNotificationQuery("Select * from __instancemodificationevent where TargetInstance isa 'Win32_UTCTime'").NextEvent();
		КонецЦикла;
		
	ИначеЕсли Вариант = "Пустой цикл" Тогда
		
		// грузит процессор
		ДатаВыхода = ТекущаяДата() + ЗадержкаСекунд;
		Пока ТекущаяДата() < ДатаВыхода Цикл
			ОбработкаПрерыванияПользователя();
		КонецЦикла;
		
	ИначеЕсли Вариант = "Sleep" Тогда
		
		// не работает
		
		scr = Новый ComОбъект("WScript.Shell"); 
		scr.Run("sleep "+Формат(ЗадержкаСекунд, "ЧДЦ=0; ЧГ="), 0, 1);
		
	ИначеЕсли Вариант = "SleepJs" Тогда
		
		// работает
		
		Скрипт = Новый ТекстовыйДокумент(); 
		Скрипт.УстановитьТекст 
		( 
		"if (WScript.Arguments.Count()==0) 
		| WScript.Quit(); 
		|else 
		| if (isNaN(parseInt(WScript.Arguments(0)))) 
		| WScript.Quit(); 
		|WScript.Sleep(WScript.Arguments(0));" 
		); 
		Скрипт.Записать(КаталогВременныхФайлов()+"sleep.js", КодировкаТекста.ANSI); 
		WshShell = Новый COMОбъект("wscript.shell"); 
		WshShell.Run("wscript.exe """+КаталогВременныхФайлов()+"sleep.js"" "+Формат(ЗадержкаСекунд*1000,"ЧГ=0"), 0, -1); 
		УдалитьФайлы(КаталогВременныхФайлов()+"sleep.js"); 
		
	ИначеЕсли Вариант = "SleepVbs" Тогда
		
		// работает
		
		Сигнатура = Формат(ТекущаяДата(), "ДФ=yyyyMMddhhmmss");
		ПутьСкрипта = КаталогВременныхФайлов()+"SleepScript"+Сигнатура+".vbs";
		СкриптФайл = Новый ТекстовыйДокумент;
		СкриптФайл.ДобавитьСтроку("WScript.Sleep("+Формат(ЗадержкаСекунд*1000, "ЧГ=0")+")");
		СкриптФайл.Записать(ПутьСкрипта, КодировкаТекста.OEM);
		WSHShell = Новый COMОбъект("WScript.Shell");
		WSHShell.Run("wscript.exe """+ПутьСкрипта+"""", 0, 1);
		УдалитьФайлы(ПутьСкрипта);
		
	ИначеЕсли Вариант = "TimeoutWS" Тогда
		
		// работает
		
		КомандаWindows = "Timeout /T " + Формат(ЗадержкаСекунд, "ЧГ=0") + " /NoBreak";
		
		WshShell = Новый COMОбъект("WScript.Shell"); 
		WshShell.Run(КомандаWindows, 0, -1);
		
	ИначеЕсли Вариант = "Timeout" Тогда
		
		// работает, показывает черное окно
		
		КомандаWindows = "Timeout /T " + Формат(ЗадержкаСекунд, "ЧГ=0") + " /NoBreak";
		ЗапуститьПриложение(КомандаWindows,,Истина);
		
	ИначеЕсли Вариант = "DynamicWrapper" Тогда
		
		// нужна библиотека
		
		Wrapper = Новый ComОбъект("DynamicWrapper"); 
		Wrapper.Register("KERNEL32.DLL", "Sleep", "i=l", "f=s"); 
		
		Wrapper.Sleep(ЗадержкаСекунд);
		
	КонецЕсли;
	
	Сообщить("^^^^^^: "+ТекущаяДата());
		
КонецПроцедуры

 

 

Скачать файлы

Наименование Файл Версия Размер
Паузы при исполнении кода (Sleep для 1с):

.epf 11,61Kb
24.11.17
14
.epf 11,61Kb 14 Скачать

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. CyberCerber 635 28.11.17 17:45 Сейчас в теме
Странно, что не работает SleepVbs. Я обычно таким методом пользуюсь, на компах с Виндовс работает.
13. swimdog 726 29.11.17 13:04 Сейчас в теме
(1) Сравнил с (7). Работает, у меня пауза была не в секундах, а в миллисекундах, поэтому я решил, что не работает.
2. Infector 165 29.11.17 07:11 Сейчас в теме
Процедура Ожидание(Секунд)
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";
	ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры	
s0u1; Grubly; Емельянов Алексей; +3 Ответить
15. swimdog 726 29.11.17 13:20 Сейчас в теме
(2) Добавил в статью
Емельянов Алексей; +1 Ответить
3. maikl007 91 29.11.17 08:04 Сейчас в теме
Все работает...

Процедура ПаузаWSH(Секунд) Экспорт
	
	ПолноеИмяФайла  = КаталогВременныхФайлов() + "sleep.vbs";
	Текст = Новый ТекстовыйДокумент;
	Текст.ДобавитьСтроку("wscript.sleep wscript.arguments(0)");
	Текст.Записать(ПолноеИмяФайла, КодировкаТекста.OEM);
	
	WshShell = Новый COMОбъект("Wscript.Shell");
	WshShell.Run("Wscript.exe """+ПолноеИмяФайла+""" "+Секунд*1000, 0, 1);
  
КонецПроцедуры
Показать
4. japopov 61 29.11.17 08:15 Сейчас в теме
Почему-то забыли для УФ асинхронный диалог вопроса? Он принимает параметр Таймаут (который нам и нужен), и заодно выводит юзеру сообщение - а обратная связь не помешает, ведь так? Я обычно вызываю что-то вроде

&НаКлиенте
Процедура ПриОткрытии(Отказ)

	СписокКнопок = Новый СписокЗначений;
	СписокКнопок.Добавить(КодВозвратаДиалога.Прервать,"Прервать");
	ЗадержкаВСекундах = 5;
	ПоказатьВопрос(Новый ОписаниеОповещения("ПриОткрытииЗавершение", ЭтаФорма), "Выполняется Супер-обработка. Подажуйста, подождите",СписокКнопок,ЗадержкаВСекундах,,"Длительная операция");

КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытииЗавершение(РезультатВопроса, ДополнительныеПараметры) Экспорт
	
	Если РезультатВопроса=КодВозвратаДиалога.Таймаут Тогда
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Вы дождались, ура!");
	Иначе
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Невтерпёж, да?");
	КонецЕсли;
	
КонецПроцедуры

Показать


Кроме очевидного - задержки, не нагружая системные ресурсы - этот метод даёт пользователю возможность прервать длительный процесс, а нам - корректно отработать это прерывание и сделать всё красиво.

Ах, да, и самое, наверное, важное: этот метод работает с любым клиентом в любой операционной системе. В отличие от.
hydro2588_2015; user1058740; SVSVSV999; adhocprog; seperblunt2; DarkUser; y.dyachenko; TreeDogNight; necropunk; jif; Yakud3a; Gluk_1C; mickey.1cx; vano-ekt; forseil; NeviD; WizaXxX; +17 Ответить
5. zqzq 21 29.11.17 08:41 Сейчас в теме
(4) +1, какой-то набор вредных советов в статье :) Если только нужно именно на сервере пауза, в очень редких случаях.

Есть ещё
ПодключитьОбработчикОжидания()

работает и в обычных и в управляемых формах.
mutoc@mail.ru; +1 1 Ответить
27. gigabyte_artur 26.12.18 12:31 Сейчас в теме
Найдено в недрах БСП:

Процедура Пауза(Секунд) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("ОбщегоНазначенияБТС.Пауза", Параметры);
	КонецЕсли;
		
	Попытка
		ФоновоеЗадание.ОжидатьЗавершения(Секунд);
	Исключение
		Возврат;
	КонецПопытки;
	
КонецПроцедуры
Показать


Платформо-независимо, работает на сервере, не нагружает процессор.
Вызов из БСП:

ОбщегоНазначенияБТС.Пауза(5);
beardlyhich; Mi4man; hydro2588_2015; KilloN; davdykin; user990914; Anything; batusai_00; Alex_Prodigy; aezdakov; QZet; json; dreamerr7; adhocprog; Vampeg; leonidt84; boogie; noon; uno-c; +19 Ответить
28. gigabyte_artur 26.12.18 12:34 Сейчас в теме
Найдено в недрах БСП:

Процедура Пауза(Секунд) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("ОбщегоНазначенияБТС.Пауза", Параметры);
	КонецЕсли;
		
	Попытка
		ФоновоеЗадание.ОжидатьЗавершения(Секунд);
	Исключение
		Возврат;
	КонецПопытки;
	
КонецПроцедуры
Показать


Платформо-независимо, работает на сервере, не загружает процессор.
Вызов из БСП (пример):

ОбщегоНазначенияБТС.Пауза(5);
beardlyhich; MrBukas; Anything; Емельянов Алексей; user774630; Alogy; Vampeg; +7 Ответить
16. bulpi 177 29.11.17 13:53 Сейчас в теме
(4)
То, что Вы предлагаете, принципиально не годится, именно из-за асинхронности. Нужна ПАУЗА! А у Вас не будет никакой паузы. Висящий вопрос в асинхронном режиме - это не пауза, т.к. программа уже пошла вовсю дальше работать.
17. japopov 61 29.11.17 14:44 Сейчас в теме
(16)
То, что Вы предлагаете, принципиально не годится, именно из-за асинхронности. Нужна ПАУЗА! А у Вас не будет никакой паузы. Висящий вопрос в асинхронном режиме - это не пауза, т.к. программа уже пошла вовсю дальше работать.


То есть, как делать формы для работы в асинхронном режиме, Вы не умеете. Но это - недостаток Вас как специалиста, а не моего ответа как алгоритма.

Подскажу для тех, кто в танке: код в методе ПриОткрытииЗавершение() выполнится только после завершения ожидания.
Переносите в него всё, что должно было отработать после паузы, и всё!

А вообще, сайт its.1c.ru, и RTFM
victorree; +1 1 Ответить
21. bulpi 177 29.11.17 17:54 Сейчас в теме
(17)
То есть, смысл моего замечания Вы не поняли. Но это - недостаток Вас как специалиста, а не моего замечания :).
Уж конечно, я понимаю, что "код в методе ПриОткрытииЗавершение() выполнится только после завершения ожидания". Но вот то, что ПОСЛЕ ПоказатьВопрос - выполнится сразу. И вот этот "гениальный" подход : "Переносите в него всё, что должно было отработать после паузы, и всё" - применим не всегда. Или для этого нужно извратиться так, как рвать гланды через Ж. Статья вообще не об этом, а о паузе. А это не ПАУЗА ( впрочем, что-то я повторяюсь, а зачем ? )
6. d_protos 29.11.17 09:33 Сейчас в теме
Статья не настолько полезна, насколько вредна.
Если нужна пауза в клиентском коде, то есть ПодключитьОбработчикОжидания() и не нужно изобретать велосипед.
Если нужна пауза в серверном коде, то что-то не так с логикой приложения.
8. ediks 329 29.11.17 10:16 Сейчас в теме
(6)
Если нужна пауза в серверном коде, то что-то не так с логикой приложения.

Вы считаете, что обработкам, выполняющимся на сервере, совсем никогда не нужна задержка выполнения?
Реальный пример кода, где обработка ждет, когда все задания отправятся на принтер. Кстати, применен один из методов паузы, описанный автором статьи:
Пока пОбъектПринтер.cCountOfPrintjobs < пКоличествоЗадачПечати И ТекущаяДата() <= ПаузаОкончание Цикл
	//Wait until all print jobs have entered the print queue
	Если пКоличествоЗадачПечати = 0 Тогда Прервать КонецЕсли; 
КонецЦикла;
9. Yimaida 35 29.11.17 10:40 Сейчас в теме
(6) пример из жизни. нужна была пауза при отправке смс, т.к. оператор устанавливал лимит на количество сообщений в очереди в секунду.
P.S. Сделал через ПодключитьОбработчикОжидания()
arsvlg; Емельянов Алексей; echo77; sasha777666; +4 Ответить
7. ediks 329 29.11.17 09:53 Сейчас в теме
(0)
3) Варианты с использованием Sleep. Насколько я понимаю, требуют наличия программы sleep.exe.

Не соглашусь с автором - вариант SleepJs прекрасно работает.

СкриптФайл  = Новый ТекстовыйДокумент;
СкриптФайл.УстановитьТекст("WScript.Sleep(5000)");
СкриптФайл.Записать(КаталогВременныхФайлов() + "clean.vbs",КодировкаТекста.ANSI);
Сообщить(ТекущаяДата());
ЗапуститьПриложение("""" + КаталогВременныхФайлов() + "clean.vbs""",, Истина);
Сообщить(ТекущаяДата());
14. swimdog 726 29.11.17 13:04 Сейчас в теме
(7) Работает, у меня пауза была не в секундах, а в миллисекундах, поэтому я решил, что не работает.
10. МихаилМ 29.11.17 11:25 Сейчас в теме
все варианты работают в windows. укажите чисто 1с метод через HTTPСоединение или ожидания блокировки
19. Darklight 22 29.11.17 16:34 Сейчас в теме
(10) Через HTTPСоединение
функция ОжидатьЧерезHTTP(Знач Таймаут)
	хтп = новый HTTPСоединение("1C.ru",11111,,,,Таймаут);
	Попытка
		хтп.получить(новый HTTPЗапрос (""));
	исключение
		
	Конецпопытки;
КонецФункции
Показать


Будет платформенонезависимо, будет работать на клиенте. Но опять-таки, не работает в безопасном режиме (хотя на сервере профиль безопасности можно настроить, чтобы работало - для КОРП лицензии сервера).

И, главное, чтобы строка соединения в "HTTPСоединение" была указана корректная - чтобы доступ к HTTP ресурсу в принципе был!
adhocprog; +1 Ответить
11. SerebanSK 26 29.11.17 11:28 Сейчас в теме
Если очень хочется ждать на сервере, то на мой взгляд наименее костыльный способ - это ожидание фоновым заданием самого себя.

Процедура ЖдатьНаСервереВФоновомЗадании(Знач Таймаут) Экспорт
		
	Ключ = Строка(Новый УникальныйИдентификатор());
	Наименование = "Фоновое ожидание";
	
	МассивПараметров = Новый Массив;
	МассивПараметров.Добавить(Таймаут);
	МассивПараметров.Добавить(Ключ);
	МассивПараметров.Добавить(Наименование);
	
	ФЗ = ФоновыеЗадания.Выполнить("ОбщегоНазначения.ЖдатьЗавершенияФонового", МассивПараметров, Ключ, Наименование);
	ФЗ.ОжидатьЗавершения();
	
КонецПроцедуры


Процедура ЖдатьЗавершенияФонового(Таймаут,Ключ,Наименование) Экспорт
	
	Попытка
		ФоновыеЗадания.ПолучитьФоновыеЗадания(Новый Структура("Наименование,Ключ", Наименование, Ключ))[0].ОжидатьЗавершения(Таймаут);
	Исключение
	КонецПопытки;	
	
КонецПроцедуры
Показать
json; adhocprog; uno-c; KEV_SZK; JohnyDeath; Evil Beaver; Krio2; Darklight; nixel; azubar; Labotamy; +11 Ответить
18. Darklight 22 29.11.17 15:48 Сейчас в теме
Ожидание на фоновом задании - самое интересное решение (сам только что хотел предложить такое же) - но, надо бы проверить как будет вести себя в файловой базе. Предложу ещё фичу - один раз запустить "бесконечное" регл. задание (аналогично ждущее завершения самого себя) - и всем остальным сеансам обращаться на ожидание завершения ФЗ этого регл. задания. Но будет одна пользовательская лицензия расходоваться на регл. задание. Но ФЗ доступны только на сервере или в толстом клиенте - но для длительного ожидания можно и в серверный контекст переходить - это не проблема.

Остальные все советы платформенозависимые (хотя некоторые подходы можно переработать так, чтобы они имели реализацию для разных платформ).
Использовать WshShell
WshShell = Новый COMОбъект("Wscript.Shell");
WshShell.Run("Wscript.exe...")

Всё же не рекомендую - 10-я версия платформы на это может ругаться, да ещё и в безопасном режиме работать не будет.
Но если надо так - то лучше "ЗапуститьПриложение(КомандаWindows,,Истина);" - по крайней мере будет работать в Windows, Linux и MacOS (c WEB-клиентом могут быть проблемы), где теперь тоже есть клиенты 1С.

Если нужно чисто на клиенте - то придётся извращаться с "ПодключитьОбработчикОжидания" - если нужно платформеннонезависимое решение, работающее в безопасном режиме, без модальности.

Но прямо среди кода остановиться так не получится - но, на мой взгляд, если такой код разбить на части через "ПодключитьОбработчикОжидания" не получится - значит там явно очень плохой дизайн.

Либо, нужно просто написать классический бесконечный цикл (думаю, что сюда попадут лишь короткие паузы - не более пары секунд- можно и покрутить проц клиента - коли уж очень нужно).

Или писать платформеннозависимый не безопасный код через вызов «ЗапуститьПриложение» или, ожидать на фоновом задании (регламентном или специально запускаемом), ждущим самого себя; с заходом в серверный контекст выполнения (если это не толстый клиент).

В общем всё ещё ждём, когда 1С встроит в платформу системную функцию паузы... давно ждём....
uno-c; Krio2; SerebanSK; +3 Ответить
12. azubar 37 29.11.17 12:27 Сейчас в теме
Можно еще так фоновое задание+блокировки:

// Процедура - Ожидание
//
// Параметры:
// Длительность - Число - длительность ожидания в секундах.
//
Процедура Ожидание(Длительность) Экспорт
 
     Идентификатор = Новый УникальныйИдентификатор;
 
     НачатьТранзакцию();
 
     Блокировка = Новый БлокировкаДанных; 
     Элемент = Блокировка.Добавить("РегистрСведений.сшпБлокировкаОчереди");
     Элемент.Режим = РежимБлокировкиДанных.Исключительный;
     Элемент.УстановитьЗначение("Идентификатор", Идентификатор); 
     Блокировка.Заблокировать();
 
     мсвПараметров = Новый Массив;
     мсвПараметров.Добавить(Идентификатор);
     Задание = ФоновыеЗадания.Выполнить("сшпОбщегоНазначения.ВыполнитьПаузу", мсвПараметров,, "Выполнить паузу "+Длительность+" сек.");
 
     Попытка
          Задание.ОжидатьЗавершения(Длительность);
          Исключение
     КонецПопытки; 
 
     ОтменитьТранзакцию();
 
КонецПроцедуры
Показать


// Процедура - Выполнить паузу
//
// Параметры:
// Идентификатор - УникальныйИдентификатор - идентификатор сессии ожидания.
//
Процедура ВыполнитьПаузу(Идентификатор) Экспорт
 
     НачатьТранзакцию();
     Блокировка = Новый БлокировкаДанных;
 
     Элемент = Блокировка.Добавить("РегистрСведений.сшпБлокировкаОчереди");
     Элемент.Режим = РежимБлокировкиДанных.Исключительный;
     Элемент.УстановитьЗначение("Идентификатор", Идентификатор);
 
     Попытка
          Блокировка.Заблокировать();
     Исключение
     КонецПопытки;
     ОтменитьТранзакцию();
 
КонецПроцедуры
Показать
20. opx 641 29.11.17 16:40 Сейчас в теме
Я думаю, что это хороший пример того как писать не надо.
24. user966794 27.04.18 21:13 Сейчас в теме
(20)Павел, здравствуйте! Пишу не по теме, но хотелось бы проконсультироваться с Вами по поводу Вашего плагина для вордпресс opcity. Как с Вами можно связаться?
22. Infector 165 30.11.17 12:34 Сейчас в теме
Думаю, что многие уже сами догадались, но все-таки нужно поотделять мух от котлет хотя бы для новичков, которые могут это читать:

Вариант с пингами:
&НаКлиенте
Процедура Ping_01(Секунд)
	
	КомандаWindows = "ping -n 1 -w "+Формат(1000 * Секунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
	WshShell = Новый COMОбъект("WScript.Shell"); 
	WshShell.Run(КомандаWindows, 0, -1); 
	
КонецПроцедуры


Трансформируется в:
&НаКлиенте
Процедура Ping_02(Секунд)
	
	КомандаWindows =  "ping -n 1 -w "+Формат(1000 * Секунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
    ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры


Аналогично Timeout, который я выложил в комментариях
&НаКлиенте
Процедура Timeout_03(Секунд)
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";
    ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры


Трансформируется в:
&НаКлиенте
Процедура Timeout_04(Секунд)            
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";

	WshShell = Новый COMОбъект("WScript.Shell"); 
	WshShell.Run(КомандаWindows, 0, -1); // Вставить содержимое обработчика.
	
КонецПроцедуры
Показать


Соответственно все эти варианты обращаются к командам, которые можно вводить через консольку операционной системы, использовать в CMD-файлах, но следует различать:
Во-первых обратиться можно к разным командам ОС (Ping, Timeout)
Во-вторых способ, которым можно обратиться - (Оператор платформы "ЗапуститьПриложение" и COMОбъект("WScript.Shell"); )

Соответственно - на клиенте "ЗапуститьПриложение" выкидывает черное окно с консолью, на сервере его никто не видит
COMОбъект("WScript.Shell") - обходится без визуальных эффектов.

А что из этого использовать - дело другое Timeout команда для задержки собственно и предназначенная, но в старых операционных системах (Windows 2000 точно, Windows XP не помню точно) отсутствовала. Проблема с CMD в те времена решалась похишением Timiout.exe с серверной операционной системы аналогичной давности и помещением в System32 на целевой машине.

А вот найти машину не поддерживающую Ping и лишенную TCP/IP напрочь уже тогда было сложно. (Хотя мне это удалось)
leemuar; Yasasha; serg_infostart; Alligator84; swimdog; +5 Ответить
23. fish249 05.12.17 09:45 Сейчас в теме
Спасибо, очень полезная статья.
25. swimdog 726 06.06.18 11:16 Сейчас в теме
Кусок функционала из БСП:

Функция ПроверитьДоступностьСервера(АдресСервера)

СистемнаяИнформация = Новый СистемнаяИнформация();
ЭтоWindows = (СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86)
Или (СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64);

Если ЭтоWindows Тогда
ШаблонКоманды = "ping %1 -n 2 -w 500";
Иначе
ШаблонКоманды = "ping -c 2 -w 500 %1";
КонецЕсли;

СтрокаКоманды = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ШаблонКоманды, АдресСервера);

Результат = ЗапуститьПрограмму(СтрокаКоманды, ПараметрыЗапускаПрограммы);
26. nordcomp 05.12.18 09:43 Сейчас в теме
Ссылка на эту статью есть в публикации, которую использовали. Взяли на заметку
29. mevgenym 86 14.03.19 12:46 Сейчас в теме
+ в копилку
типовой из подсистемы Меркурий (первая версия подсистемы опубликована в июле 2018)

Функция Ожидать(ВремяОжидания) Экспорт
	
	Если ВремяОжидания <> 0 Тогда
		
		НастройкиПрокси = Новый ИнтернетПрокси(Ложь);
		НастройкиПрокси.НеИспользоватьПроксиДляЛокальныхАдресов = Истина;
		НастройкиПрокси.НеИспользоватьПроксиДляАдресов.Добавить("127.0.0.0");
		
		Попытка
			Loopback = Новый HTTPСоединение(
				"127.0.0.0",,,,НастройкиПрокси,
				ВремяОжидания);
			Loopback.Получить(Новый HTTPЗапрос());
		Исключение
			ВремяОжидания = 0;
		КонецПопытки;
		
	КонецЕсли;
	
КонецФункции
Показать


Подобный вариант уже предлагали выше и обсуждали на мисте
https://www.forum.mista.ru/topic.php?id=686617

понравилось :)
Функция Слиип(Сек)
  КонДата = ТекущаяДата() + Сек;
  Пока ТекущаяДата() < КонДата Цикл
      ОтправитьПисьмоНуралиеву("Боря добавь Sleep() в 1С");
  КонецЦикла;
КонецФункции
KilloN; EMelihoff; acanta; uno-c; +4 Ответить
30. uno-c 161 19.03.19 01:35 Сейчас в теме
(29)Сами же мучаются, но написать встроенную в язык паузу - все никак ... Автору спасибо и за статью, и за то, что статья получилась собиратель полезных комментариев. Конструктивным комментаторам тоже ++. Мой пример серверной потребности в паузе: в регламентном задании отправляю на сторонний php скрипт картинки порциями, скрипт их закачивает и параллельно создает миниатюры, иногда не успевает к моей следующей отправке порции картинок - нужна пауза несколько секунд.
31. juker 226 02.06.19 18:14 Сейчас в теме
Спасибо автору и комьюнити, не пришлось изобретать велосипед.
32. SirYozha 204 04.06.19 12:12 Сейчас в теме
Еще из БСП (обработка УправлениеДоступом):
&НаКлиенте
Процедура Пауза(ИнтервалОжидания)
	
	ЗапуститьСОжиданиемЗавершенияРаботыПриложения("timeout /t " + Формат(ИнтервалОжидания, "ЧГ=0"), "Пауза", 0);
	
КонецПроцедуры

&НаКлиенте
Функция ЗапуститьСОжиданиемЗавершенияРаботыПриложения(СтрокаЗапуска, Контекст, ВидОкнаЗапускаемогоПриложения = 1)
	
#Если МобильныйКлиент Тогда
	ПоказатьПредупреждение(, НСтр("ru = 'Инструмент ""Управление доступом"" не доступен в веб-клиенте и мобильном клиенте, необходимо использовать тонкий клиент.'"));
	Возврат Неопределено;
#Иначе
	КодВозврата = -1;
	СистемныйПроцесс = Новый COMОбъект("WScript.Shell");
	
	Попытка
		КодВозврата = СистемныйПроцесс.Run(СтрокаЗапуска, ВидОкнаЗапускаемогоПриложения, Истина);
	Исключение
		ТекстОшибки = НСтр("ru = 'Ошибка запуска в %1: %2
			|Строка запуска: %3'");
		
		ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			ТекстОшибки, Контекст, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()), СтрокаЗапуска);
		
	КонецПопытки;
	
	Возврат КодВозврата;
#КонецЕсли

КонецФункции
Показать
33. scream 50 15.10.19 14:14 Сейчас в теме
34. andryandry 100 08.12.19 14:59 Сейчас в теме
САМЫЙ КОШЕРНЫЙ SLEEP - платформонезависимый, не требует прав пользователя\расширения на запуск внешних процессов

Процедура Sleep(КоличествоСекунд)
   Попытка
     Соединение = Новый HTTPСоединение("127.0.0.0",,,,,КоличествоСекунд);
     Соединение.Получить(Новый HTTPЗапрос());
   Исключение
   Конецпопытки;	
КонецПроцедуры
Показать
unichkin; KUAvanesov; stvorl; curdate; Leo_A; acanta; +6 Ответить
35. user799503 01.02.20 12:01 Сейчас в теме
Делаем что-то

Для н=1 По 75000 Цикл
//ожидание
КонецЦикла;

Делаем что-то другое

у меня 75000 - приблизительно 2/3 секунды
36. user799503 02.02.20 09:14 Сейчас в теме
Кстати с секундной задержкой ещё проще

ТДата=ТекущаяДата()+х, где х - это количество целых секунд.

Пока ТДата>ТекущаяДата() Цикл
КонецЦикла;
AnKonAlm; +1 Ответить
37. swimdog 726 02.02.20 17:33 Сейчас в теме
(36) Вариант 2 в статье. Там же написаны его минусы.
38. user1096076 09.03.20 17:18 Сейчас в теме
Мой вариант:

ВремяЗавершения = ТекущаяДата() + Время;
Пока ТекущаяДата() < ВремяЗавершения Цикл
КонецЦикла;
AnKonAlm; +1 Ответить
39. nuctoh 27 30.04.20 12:18 Сейчас в теме
(38) Сильно нагружает процессор и жрет память. Никогда так не делай!
40. user1096076 27.05.20 08:46 Сейчас в теме
(39) так в КА типовой сделано)).
41. swimdog 726 31.05.20 12:43 Сейчас в теме
(40) Это потому, что они инфостарт мало читают.
Оставьте свое сообщение

См. также

Вам нравятся запросы в 1С? Промо

Практика программирования Разработка v8 v8::Запросы 1cv8.cf Абонемент ($m)

Речь не только о том, что простейший запрос с "легальным" оформлением растянется на пол-экрана, речь еще обо всем, что нужно написать "в нагрузку" к тексту запроса. Все эти "Новый Запрос", "УстановитьПараметр" и последующие пляски с обработкой результата... Пора с этим заканчивать!

1 стартмани

03.07.2019    20346    4    m-rv    86    

Интерактивная справка по объектам 1С (автономное расширение)

Практика программирования Работа с интерфейсом v8 ERP2 Абонемент ($m)

База знаний, подключаемая к объектам основной базы. Ведётся интерактивно, формируется в виде статей прямо в 1С (текст, картинки, таблицы, ссылки). Есть возможность прикрепления файлов, привязки к объектам 1С, возможности рейтинга и комментирования пользователями.

3 стартмани

29.09.2020    5381    24    sapervodichka    29    

Конвейер проверки качества кода

Инструментарий разработчика Практика программирования Математика и алгоритмы v8 1cv8.cf Абонемент ($m)

Jenkinsfile для выполнения проверки качества кода. Собирает информацию с АПК, EDT и BSL-LS. Сопоставляет ошибки с гит-репозиторием, выгруженным ГитКонвертором. Отправляет в Сонар.

3 стартмани

04.09.2019    24280    22    Stepa86    45    

Алгоритмы поиска пути в графе

Практика программирования Разработка v8 1cv8.cf Абонемент ($m)

Реализуем алгоритмы поиска пути в графе на платформе 1С 8.3, такие как алгоритм А*, поиск в ширину, жадный поиск, алгоритм Дейкстры и вконце волновой.

1 стартмани

09.07.2019    17396    11    RonX01    10    

ВСТАВИТЬ В Справочник.Номенклатура (Код, Наименование) ЗНАЧЕНИЯ ("001", "Новый товар") Промо

Практика программирования v8 v8::Запросы 1cv8.cf Абонемент ($m)

Вас не обманывают ваши глаза, это запрос на изменение данных! И это работает без прямого доступа к БД, регистрации и смс.

1 стартмани

01.06.2018    30276    86    m-rv    57    

Создание Проекта и Задач в проекте из 1С 8.3 в MS Project 2016 (обычные формы)

Внешние источники данных v8 УПП1 Россия УУ Абонемент ($m)

Внешняя обработка (используя методы HTTP запросов и Json) для создания из 1С Проекта в MS Project Server 2016 и создание Задачи в Проекте. Обработка тестировалась на конфигурации 1С:УПП+CRM (SQL) 1.3.112/1.4.11 платформа 1С Предприятие: 8.3.10.2252, обычные формы.

2 стартмани

04.12.2018    4598    8    SurmachAU    0    

Работа с публикациями "Инфостарт"

Практика программирования О сообществе WEB v8 УУ Абонемент ($m)

Работа с рублевыми публикациями на сайте "Инфостарт": ведение клиентов, заказов, обновление файлов публикации, рассылка обновлений.

1 стартмани

13.09.2018    21591    13    RocKeR_13    16    

HTTP Сервисы: Путь к своему сервису. Часть 3

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Продолжение статьи «HTTP Сервисы: Путь к своему сервису. Часть 2». В предыдущих частях мы использовали только Get, в этой части поговорим о других методах и длительных операциях.

1 стартмани

27.08.2018    36907    54    dsdred    15    

Заполняем по шаблону (по умолчанию) Промо

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Простой в подключении, универсальный и достаточно удобный механизм заполнения реквизитов произвольных документов/справочников значениями по умолчанию. Реализован в расширении, но может быть и непосредственно включен практически в любую конфигурацию на управляемых формах простым копированием одной формы и двух команд. Весь код в статье.

1 стартмани

08.02.2018    28091    19    mvxyz    17    

Позиционирование в помещении с помощью нейросети по сигналу Wi-Fi. Интерактивная карта склада в 1С с показом позиции

Инструментарий разработчика Практика программирования v8 Абонемент ($m)

Данная публикация содержит в себе редактор и интерактивную карту склада или иного помещения, на которой в реальном времени отображается позиция устройства, координаты которого вычисляются по уровням сигнала нескольких роутеров Wi-Fi. В статье и приложенным к ней разработкам предлагаются инструменты и методика для реализации вычисления точной геопозиции внутри помещений с помощью нейронной сети. Конфигурация написана на релизе 1С:Предприятие 8.3.12.1412, клиентское приложение имеет минимальный уровень совместимости SDK -16.

5 стартмани

09.08.2018    27952    26    informa1555    26    

Работа с данными выбора

Практика программирования Работа с интерфейсом v8 Россия Абонемент ($m)

В управляемом интерфейсе заложена мощная возможность описывать связи реквизитов формы через параметры. Установка параметров связей позволяет ограничить выбор данных так, чтобы целостность данных была обеспечена на этапе ввода. Однако без дополнительного программирования задать можно только самые простые связи. Такие условия связи, как зависимость от реквизита через точку или зависимость через дополнительное отношение, заданное в регистре сведений - уже задать без программирования не получится.

1 стартмани

17.07.2018    46811    17    kalyaka    16    

Полезные примеры составления схемы компоновки данных #2

Практика программирования v8 v8::СКД 1cv8.cf Абонемент ($m)

Еще один набор примеров как решить частные задачи в СКД

1 стартмани

22.05.2018    30585    11    SITR-utyos    13    

Нечеткий поиск одним запросом Промо

Практика программирования v8 1cv8.cf Абонемент ($m)

Использование механизма полнотекстового поиска в 1С не всегда оправдано, т.к. построение индекса и поддержание его в актуальном состоянии может значительно нагружать систему. Предлагаемая реализация нечеткого поиска методом N-грамм выполняется одним запросом, что позволяет производить поиск в любой таблице и не требует предварительного построения индекса.

1 стартмани

28.12.2015    27550    70    vasvl123    9    

Печатная форма, сделанная как расширение конфигурации для БП 3.0. Новые возможности БСП

Практика программирования Универсальные печатные формы v8 БП3.0 Абонемент ($m)

Печатные формы на внешних обработках скоро канут в лету. На смену им приходят ПФ, реализованные в виде расширений конфигурации. Не нашел на сайте примеров таких расширений. Привожу пример подобного расширения для БП 3.0.

1 стартмани

06.12.2017    26893    52    kwazi    6    

Макет в СКД - пример всех возможных типовых вариантов

Практика программирования Инструментарий разработчика v8 v8::СКД 1cv8.cf Абонемент ($m)

Макет СКД: наглядное представление того, что, как и куда выводится при типовых настройках.

1 стартмани

09.11.2017    21771    76    freelancer    4    

Telegram-боты

Практика программирования v8 Абонемент ($m)

Описание теории, разбор архитектуры и пример реализации telegram-ботов. Сразу скажу, со структурированием изложения мало что могу поделать. :) редакция от 18.07.2018 Правки последней редакции выделены жирным.

1 стартмани

01.09.2017    32267    132    PLAstic    59    

1С: Предприятие + корпоративный чат, как наладить оперативные уведомления за 10 минут Промо

Практика программирования v8 Абонемент ($m)

Как сделать автоматические уведомления о разных событиях из 1С в корпоративный чат MyChat для сотрудников компании

1 стартмани

14.08.2016    47957    36    Demanoidos    60    

Умный дом на 1С + ардуино

Практика программирования v8 Абонемент ($m)

Конфигурация для автоматизации быта программиста 1C и не только. В данной статье будет рассказано, как можно использовать 1С для задач, не входящих в стандартные рамки этой платформы. Например, управление домом. В качестве периферии для подключения будет использован микроконтроллер (МК) Ардуино, но на нём не будет никакой логической нагрузки, весь процесс будет проходить на сервере 1С. Работа с пинами ввода/вывода происходит напрямую из 1С.

1 стартмани

07.08.2017    22599    21    sasha777666    63    

Расширения конфигураций 1С: учимся перехватывать методы

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

В этой статье я на примерах разберу некоторые механизмы расширений конфигураций 1С. А именно «перехваты» методов модуля объекта и «перехваты» событий формы и элементов формы. Данная статья написана с учебными целями, чтобы показать, как при помощи расширений конфигурации можно делать такие доработки, ради которых раньше приходилось снимать конфигурацию с поддержки.

1 стартмани

30.05.2017    128386    13    signum2009    48    

Регулярные выражения – это просто. Построитель и отладчик регулярных выражений

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Предлагается к использованию построитель регулярных выражений. Выполненный в виде внешней обработки, он позволит строить сложно-структурированные выражения на основе параметрического описания, тестировать их, и в результате получить программный код 1С.

1 стартмани

13.03.2017    31254    112    romasna    49    

Быстрое определение интервалов в запросе Промо

Практика программирования v8 Абонемент ($m)

В статье описывается новый метод определения интервалов между данными различных записей в запросе. В отличие от общеизвестного метода, время работы предлагаемого метода зависит от объема данных ЛИНЕЙНО. Это обеспечивает ему значительный выигрыш по быстродействию на больших объемах данных. В качестве иллюстрации возможностей метода приведен отчет, показывающий гистограмму распределения времени между продажами.

1 стартмани

01.10.2015    51271    35    ildarovich    41    

Распознавание текста с помощью нейросетей Google Cloud Vision и 1С

Практика программирования v8 1cv8.cf Абонемент ($m)

Возможности Google Cloud Vision в распознавании текста.

1 стартмани

08.02.2017    28678    124    kiv1c    18    

Графическая схема. Управление при помощи XDTO.

Практика программирования v8 Абонемент ($m)

В статье описывается методика программного управления элементами графической схемы при помощи механизма XDTO. Приложена готовая к использованию библиотека функций для создания и удаления графических объектов, а также для связи элементов схемы соединительными линиями.

2 стартмани

16.01.2017    22042    105    Alxby    23    

Простой редактор плана помещения JavaScript

Практика программирования Работа с интерфейсом v8 1cv8.cf Абонемент ($m)

На ресурсе сейчас очень много решений, которые позволяют редактировать карты, используя географические схемы. Так же много решений, которые позволяют редактировать объекты онлайн веб-карт. Мне же нужно было простое решение, для того чтобы расставить квадратные объекты на плане, показать их пользователю. Ну и распечатать, опять же. Я решил написать простенький редактор на JavaScript с использованием библиотеки Raphael.

1 стартмани

23.11.2016    20901    94    igel9780    22    

Хранение файлов в томах на диске (для УПП 1.3) Промо

Практика программирования v8 УПП1 Абонемент ($m)

Доработка типовой УПП 1.3 в плане хранения присоединенных файлов вне базы данных

2 стартмани

05.06.2016    57068    10    wowik    32    

Работа с двоичными данными на примере чтения файлов изображений. Новые возможности 8.3.9

Практика программирования WEB v8 1cv8.cf Россия Абонемент ($m)

В статье приводятся новые функции по работе с двоичными данными, появившимися в версии платформы 8.3.9 , на примере анализа формата и размера изображений. А также пример отправки изображения через API ВКонтакте с помощью новых объектов (без использования ОбъединитьФайлы())

1 стартмани

14.11.2016    25543    16    Anton64    22    

Загрузка файлов на сервер с прогрессом и докачкой

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Пример использования новых возможностей платформы 8.3.9 по низкоуровневой работе с двоичными данными для инкрементальной передачи файлов на сервер.

1 стартмани

04.10.2016    13198    53    mrstomak    21    

Несколько шаблонов для доработки типовых конфигураций

Практика программирования Инструментарий разработчика v8 v8::УФ Абонемент ($m)

Предлагаю несколько каркасов для создания новых объектов в типовых конфигурациях. Это выжимка из кода нескольких конфигураций, которая позволит быстро и красиво создавать и дорабатывать объекты метаданных с соблюдением идеологии исходной системы

1 стартмани

03.10.2016    36499    95    json    25    

HTTP-сервис: отчеты [Расширение]

Практика программирования Работа с интерфейсом v8 1cv8.cf Абонемент ($m)

Это HTTP-сервис, который возвращает почти любой отчет в HTML, XLSX или в JSON. Сохраните вариант отчета, получите на него ссылку и можно получить данные без захода в 1С. Работает в конфигурациях на основе БСП 2.3.3+, для отчетов на СКД и в 1С 8.3.8+

2 стартмани

30.08.2016    26633    135    Stepa86    15    

Использование методов глобального контекста в системе компоновки данных или недокументированные возможности СКД

Практика программирования Математика и алгоритмы v8::УФ v8::СКД 1cv8.cf Абонемент ($m)

Прочитал на форуме, что СтрРазделить() и ТекущаяДата() работают в языке выражений системы компоновки данных. Почитал справку, там ничего не нашёл, поэтому не поверил. Посмотрел на практике – и правда работает… В данной статье попытался привести весь перечень методов, работающих в СКД, но не описанных в документации.

1 стартмани

05.08.2016    37174    26    klinval    40    

Недокументированное использование стандартных форм Upd.

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Вам не хватает возможностей в платформе 1С или у Вас нет времени на углубленное изучение платформы 1С? Рассмотрены возможности использования стандартных форм, вызываемых из платформы.

1 стартмани

26.07.2016    28101    76    ZhokhovM    60    

БСП 2.3 и БСП 3.0: Просто про выполнение внешней обработки в фоне (c индикацией прогресса выполнения)

Инструментарий разработчика Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

Простое пояснение о том, как сделать внешнюю обработку с фоновым выполнением и индикацией процесса для любой конфигурации на основе БСП 2.3.2. UPDATE 20/09/19: добавлен вариант обработки с индикацией процента выполнения и статусом выполнения для БСП 3.0.

1 стартмани

18.05.2016    61017    178    rozer    65    

Остатки на каждый день в запросе

Практика программирования Учет ТМЦ Учет ТМЦ v8 1cv8.cf УУ Абонемент ($m)

Запрос формирует остатки товаров на каждый день в пределах выбранного периода.

1 стартмани

26.04.2016    58033    19    arakelyan    18    

Еще один способ расчета остатков на каждый день в запросе

Математика и алгоритмы Практика программирования v8 Абонемент ($m)

Предлагается новый способ расчета остатков на каждый день (час, минуту, секунду) в запросе. Способ не требует предварительного формирования таблицы дат и также подходит для расчета курсов валют, цен номенклатуры и других периодических сведений на каждую дату периода. На больших объемах данных предлагаемый способ может превосходить по быстродействию ранее известные методы из-за линейной (в лучшем случае) зависимости трудоемкости от длины периода.

1 стартмани

24.04.2016    34356    48    ildarovich    23    

Вывод печатных форм с запросом данных в форму "Печать документов" из подсистемы БСП "Печать".

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

Все не раз видели, как в типовых конфигурациях, построенных на основе БСП (Библиотека стандартных подсистем), печатные формы, построенные на основе Табличного документа, выводятся в специальную форму "ПечатьДокументов". Эта форма входит в состав подсистемы "Печать" из БСП. При разработке своих печатных форм, иногда необходимо запросить у пользователя дополнительные данные необходимые для печати. Тут встает вопрос, как в этом случае вывести печатную форму в форму "Печать документа". В этой статье я рассмотрю, как реализовать вывод печатной формы в упомянутую форму из подсистемы "Печать", в случае если мы хотим перед выводом печатной формы запросить у пользователя дополнительные данные. Здесь будут рассмотрены два случая: когда реализуется печатная форма с использованием подсистемы "Дополнительные отчеты и обработки" и когда печатная форма добавляется в конфигурацию в режиме конфигуратора, т.е. вносятся изменения в типовую конфигурацию.

1 стартмани

29.03.2016    88983    176    lopatin    14    

Выполнение JavaScript кода из 1С в объекте Поле HTML Документа (HTML 5) и вызов события в 1С ПриНажатии

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Пример выполнения JS кода из 1С в Поле HTML Документа под управляемыми формами, с удобным получением результата в 1С(С помощью вызова привязанного события ПриНажатии к элементу ПолеHTMLДокумента)

1 стартмани

22.03.2016    80532    158    igo1    54    

Количество дней недели (понедельников/вторников/...) в заданном диапазоне одним запросом

Практика программирования v8 Абонемент ($m)

При реализации периодического авто-заполнения маршрутных листов по графику (недельному) необходимо было просчитать стоимость всего периода, с условием выездов только по определенным дням. Заморачиваться с обходом результата не хотелось. Пришлось написать "Небольшой" запрос.

1 стартмани

03.03.2016    18169    1    Alexander.Shvets    5    

Простые радости жизни программиста 1С: выбор типа значения

Работа с интерфейсом Практика программирования v8 1cv8.cf Абонемент ($m)

Предлагаемая в работе обработка включает обычную и управляемую формы, которые максимально точно реализуют функциональность системного диалога выбора типа в толстом клиенте обычное приложение (включая оформление диалога). Эти формы имеют дополнительные интерфейсные удобства и могут быть использованы в качестве альтернативных диалогов выбора типа.

1 стартмани

17.02.2016    49693    50    yuraos    17    

Отображение прогресса выполнения длительных операций в БСП и их отладка в текущем сеансе.

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Абонемент ($m)

В статье описан способ исполнения длительных операций в конфигурациях, в которых используется библиотека стандартных подсистем, с визуализацией прогресса исполнения и отображения хода обработки данных. Также дается краткое описание процесса отладки длительных операций в текущем сеансе.

1 стартмани

17.02.2016    54607    178    balanton    23    

Яндекс.Деньги "Благотворительность"

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Яндекс.Деньги теперь в 1С. Форма для приема благотворительных взносов. Форму легко сделать и вставить на любую страницу сайта или блога. Платежи будут приходить на ваш кошелек. На форме есть три способа платежа: из кошелька, с банковской карты, с баланса мобильного.

1 стартмани

16.02.2016    23146    8    Tatitutu    5    

Мастер рассылки e-mail 2.2 для управляемых форм

Практика программирования Email v8 v8::УФ ERP2 БП3.0 УТ11 Абонемент ($m)

Для пользователей: переделанный из старый разработки под 8.2 с использованием библиотеки Мастер рассылки e-mail 2.2 (ERP, УТ, БП) (Только управляемые формы), который теперь может запускаться под любой версией платформы с разрешенными или запрещенными модальными/синхронными вызовами в конфигурации. Также удобный выбор e-mail и их владельцев с помощью отбора динамического списка по любым критериям и галочки исключения.

1 стартмани

29.12.2015    36942    19    milkers    4