Сохранение запроса со всеми параметрами и временными таблицами

Публикация № 1054984

Разработка - Универсальные функции

Запрос сохранение параметры временные таблицы консоль запросов

20
Функция сохранения запроса со всеми параметрами и временными таблицами в формате *.q1c для открытия в консоли запросов с диска ИТС.

Предисловие

Наверное у каждого программиста 1С есть консоль запросов для управляемого приложения с диска ИТС. Она позволяет сохранять и открывать файлы в формате *.q1c, который представляет собой обычный xml. Я написал функцию, которая позволяет во время отладки сохранить запрос со всеми параметрами в формате *.q1c, чтобы можно было затем открыть его в режиме Предприятие с уже установленными параметрами и временными таблицами. 

Код основной функции и вспомогательных функций и процедур

Функция СохранитьЗапрос(Запрос, ИмяКаталогаИлиПолноеИмяФайла) Экспорт
	
	Попытка
		ИмяКаталогаСоСлэшем = ИмяКаталогаИлиПолноеИмяФайла + ?(Прав(ИмяКаталогаИлиПолноеИмяФайла,1)="\", "", "\");
		ИмяЗапроса = "Запрос_"+Формат(ТекущаяДата(), "ДФ=гггг-ММ-дд_ЧЧ-мм-сс");
		ПолноеИмяФайла  = ИмяКаталогаСоСлэшем + ИмяЗапроса + ".q1c";

		МассивСоздаваемыхВТекстеЗапросаВТ = МассивСоздаваемыхВременныхТаблицЗапроса(Запрос.Текст);
		
		//Добавим в начало текста запроса выборку во временные таблицы
		ТекстВыборкиВоВременныеТаблицы = "";
		МассивДанныхПоВременнымТаблицам = Новый Массив;
		Если Запрос.МенеджерВременныхТаблиц <> Неопределено Тогда
			Для Каждого ВременнаяТаблица Из Запрос.МенеджерВременныхТаблиц.Таблицы Цикл
				//Исключим временные таблицы, которые создаются в тексте этого запроса
				Если МассивСоздаваемыхВТекстеЗапросаВТ.Найти(ВременнаяТаблица.ПолноеИмя) <> Неопределено Тогда
					Продолжить;
				КонецЕсли;
				
				ТекРезультатЗапроса = ВременнаяТаблица.ПолучитьДанные();
				ТаблицаПустая = ТекРезультатЗапроса.Пустой();
				//Если временная таблица пустая, то в текст выборки добавим создание этой таблицы, но в МассивРезультатовВТ записывать не будем
				ТекстВыборкиВоВременныеТаблицы = ТекстВыборкиВоВременныеТаблицы + ПолучитьТекстВыборкиКолонокТаблицыЗначенийВЗапросе(ВременнаяТаблица.ПолноеИмя, ТекРезультатЗапроса.Колонки, ТаблицаПустая);
				Если НЕ ТаблицаПустая Тогда
					МассивДанныхПоВременнымТаблицам.Добавить(Новый Структура("ИмяВременнойТаблица,РезультатЗапроса", ВременнаяТаблица.ПолноеИмя, ТекРезультатЗапроса));
				КонецЕсли;
			КонецЦикла;
		КонецЕсли;
		
		ЗаписьXML = Новый ЗаписьXML;
		ЗаписьXML.ОткрытьФайл(ПолноеИмяФайла, "utf-8");
		ЗаписьXML.ЗаписатьОбъявлениеXML();

		ЗаписьXML.ЗаписатьНачалоЭлемента("querylist");

			ЗаписьXML.ЗаписатьНачалоЭлемента("query");
			ЗаписьXML.ЗаписатьАтрибут("name", ИмяЗапроса);

				ЗаписьXML.ЗаписатьНачалоЭлемента("text");
				ЗаписьXML.ЗаписатьТекст(ТекстВыборкиВоВременныеТаблицы + Запрос.Текст);
				ЗаписьXML.ЗаписатьКонецЭлемента(); //text

				ЗаписьXML.ЗаписатьНачалоЭлемента("parameters");

					Для Каждого КЗ Из Запрос.Параметры Цикл
						ЗаписьXML.ЗаписатьНачалоЭлемента("parameter");
						ЗаписьXML.ЗаписатьАтрибут("name", КЗ.Ключ);

						ЗначениеПараметра = КЗ.Значение;
						ТипЗнчПараметра = ТипЗнч(ЗначениеПараметра);

						Если ТипЗнчПараметра  = Тип("Граница") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "Граница");
							ЗаписьXML.ЗаписатьНачалоЭлемента("divide");
								ЗаписьXML.ЗаписатьАтрибут("type", "Дата");
								ЗаписьXML.ЗаписатьАтрибут("valueDiv", Строка(ЗначениеПараметра.ВидГраницы));
								ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ЗначениеПараметра.Значение));
							ЗаписьXML.ЗаписатьКонецЭлемента(); //divide

						ИначеЕсли ТипЗнчПараметра = Тип("МоментВремени") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "МоментВремени");
							ЗаписьXML.ЗаписатьНачалоЭлемента("item");
								ЗаписьXML.ЗаписатьАтрибут("type", XMLТипЗнч(ЗначениеПараметра.Ссылка).ИмяТипа);
								ЗаписьXML.ЗаписатьАтрибут("valueRef", XMLСтрока(ЗначениеПараметра.Ссылка));
								ЗаписьXML.ЗаписатьАтрибут("valueDate", XMLСтрока(ЗначениеПараметра.Дата));
							ЗаписьXML.ЗаписатьКонецЭлемента(); //item

						ИначеЕсли ТипЗнчПараметра = Тип("СписокЗначений") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "СписокЗначений");
							ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, ЗначениеПараметра.ВыгрузитьЗначения());
							
						ИначеЕсли ТипЗнчПараметра = Тип("Массив") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "СписокЗначений");
							ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, ЗначениеПараметра);

						ИначеЕсли ТипЗнчПараметра = Тип("ТаблицаЗначений") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "ТаблицаЗначений");
							ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, ЗначениеПараметра, Ложь);

						Иначе
							ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ЗначениеПараметра));
							ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ЗначениеПараметра));

						КонецЕсли;

						ЗаписьXML.ЗаписатьКонецЭлемента(); //parameter
					КонецЦикла;

					//Все не пустые временные таблицы, создание которых мы добавили ранее к тексту запроса, запишем в параметры запроса как таблицы значений
					Если Запрос.МенеджерВременныхТаблиц <> Неопределено Тогда
						Для Каждого ТекСтрока Из МассивДанныхПоВременнымТаблицам Цикл
							тзВременнаяТаблица = ТекСтрока.РезультатЗапроса.Выгрузить();
							ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, тзВременнаяТаблица, Истина, ТекСтрока.ИмяВременнойТаблица);
						КонецЦикла;
					КонецЕсли;					
						
				ЗаписьXML.ЗаписатьКонецЭлемента(); //parameters

			ЗаписьXML.ЗаписатьКонецЭлемента(); //query
		
		ЗаписьXML.ЗаписатьКонецЭлемента(); //querylist
		
		ЗаписьXML.Закрыть();
		
		Возврат "Запрос с параметрами успешно сохранен в файл " + ПолноеИмяФайла;
		
	Исключение
		Возврат "Не удалось записать запрос с параметрами в файл по причине: " + ОписаниеОшибки();
		
	КонецПопытки;

КонецФункции

Функция ПолучитьИмяТипаЗначенияXML(ЗначениеПараметра)
	
	ТипЗнчПараметра = ТипЗнч(ЗначениеПараметра);
	
	Если ТипЗнчПараметра = Тип("Строка") ИЛИ ТипЗнчПараметра = Тип("Неопределено") Тогда
		Возврат "Строка";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Число") Тогда
		Возврат "Число";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Дата") Тогда
		Возврат "Дата";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Булево") Тогда
		Возврат "Булево";
	
	Иначе
		Возврат XMLТипЗнч(ЗначениеПараметра).ИмяТипа;
	
	КонецЕсли;

КонецФункции

Процедура ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, Массив)

	Для Каждого ТекущееЗначение Из Массив Цикл
		ЗаписьXML.ЗаписатьНачалоЭлемента("item");

			ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ТекущееЗначение));
			ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ТекущееЗначение));

		ЗаписьXML.ЗаписатьКонецЭлемента(); //item
	КонецЦикла;

КонецПроцедуры

Процедура ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, Таблица, ПараметрЦеликом, ИмяПараметра="")

	Если ПараметрЦеликом Тогда
		ЗаписьXML.ЗаписатьНачалоЭлемента("parameter");
		ЗаписьXML.ЗаписатьАтрибут("name", ИмяПараметра);
		ЗаписьXML.ЗаписатьАтрибут("type", "ТаблицаЗначений");
	КонецЕсли;
	
	ЗаписьXML.ЗаписатьАтрибут("colcount", Формат(Таблица.Колонки.Количество(), "ЧН=0; ЧГ=0"));
	ЗаписьXML.ЗаписатьАтрибут("rowcount", Формат(Таблица.Количество(), "ЧН=0; ЧГ=0"));
	
	ТекИндексСтроки = 0;
	Для Каждого ТекСтрокаТЗ Из Таблица Цикл
		ТекИндексКолонки = 0;
		Для Каждого ТекКолонкаТЗ Из Таблица.Колонки Цикл
			ЗаписьXML.ЗаписатьНачалоЭлемента("item");
			
			ТекущееЗначение = ТекСтрокаТЗ[ТекКолонкаТЗ.Имя];
			
			ЗаписьXML.ЗаписатьАтрибут("nameCol", ТекКолонкаТЗ.Имя);
			ЗаписьXML.ЗаписатьАтрибут("row", Формат(ТекИндексСтроки, "ЧН=0; ЧГ=0"));
			ЗаписьXML.ЗаписатьАтрибут("col", Формат(ТекИндексКолонки, "ЧН=0; ЧГ=0"));
			ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ТекущееЗначение));
			ЗаписьXML.ЗаписатьАтрибут("length", "0");
			ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ТекущееЗначение));
			
			ЗаписьXML.ЗаписатьКонецЭлемента(); //item
			
			ТекИндексКолонки = ТекИндексКолонки + 1;
		КонецЦикла;

		ТекИндексСтроки = ТекИндексСтроки + 1;
	КонецЦикла;
	
	Если ПараметрЦеликом Тогда
		ЗаписьXML.ЗаписатьКонецЭлемента(); //parameter
	КонецЕсли;
КонецПроцедуры

Функция МассивСоздаваемыхВременныхТаблицЗапроса(ТекстЗапроса)

	Перем МассивВТ;
	
	МассивВТ = Новый Массив;
	
	//Запрос может не открываться объектом СхемаЗапроса, но при этом выполняться,
	//в этой ситуации лучше вернуть пустой массив, чем завершить работу с ошибкой
	Попытка
		СхемаЗапроса = Новый СхемаЗапроса();
		СхемаЗапроса.УстановитьТекстЗапроса(ТекстЗапроса);
		Для Каждого Пакет Из СхемаЗапроса.ПакетЗапросов Цикл
			Если ТипЗнч(Пакет) = Тип("ЗапросВыбораСхемыЗапроса") Тогда
				Если ЗначениеЗаполнено(Пакет.ТаблицаДляПомещения) Тогда
					МассивВТ.Добавить(Пакет.ТаблицаДляПомещения);
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	Исключение
	КонецПопытки;
	
	Возврат МассивВТ;

КонецФункции

Функция ПолучитьТекстВыборкиКолонокТаблицыЗначенийВЗапросе(ИмяПараметра, Колонки, ПустаяТаблица)

	Перем Текст;
	
	ПоляТаблицы = "";
	Для Каждого ТекКолонка Из Колонки Цикл
		Если ПоляТаблицы <> "" Тогда
			ПоляТаблицы = ПоляТаблицы + "
			|	";
		Иначе
			ПоляТаблицы = ПоляТаблицы + "	";
		КонецЕсли;
		
		СтруктураТипа = СтруктураТипаКолонкиДляЗапроса(ТекКолонка.ТипЗначения.Типы());
		
		Если ПустаяТаблица Тогда
			ПоляТаблицы = ПоляТаблицы + СтруктураТипа.ЗначениеПоУмолчанию + " КАК "+ТекКолонка.Имя + ",";
			
		Иначе
			Если СтруктураТипа.ИмяДляПриведенияТипов <> "" Тогда
				ПоляТаблицы = ПоляТаблицы + "ВЫРАЗИТЬ(Т."+ТекКолонка.Имя + " КАК "+СтруктураТипа.ИмяДляПриведенияТипов+") КАК "+ТекКолонка.Имя + ",";
			Иначе
				ПоляТаблицы = ПоляТаблицы + "Т."+ТекКолонка.Имя + " КАК "+ТекКолонка.Имя + ",";
			КонецЕсли;
			
		КонецЕсли;
	КонецЦикла;
	//Уберем последнюю запятую
	ПоляТаблицы = Лев(ПоляТаблицы, СтрДлина(ПоляТаблицы)-1);
	
	Текст = 
	"ВЫБРАТЬ
	|"+ПоляТаблицы+"
	|ПОМЕСТИТЬ "+ИмяПараметра;
	
	Если НЕ ПустаяТаблица Тогда
		Текст = Текст + "
		|ИЗ
		|	&"+ИмяПараметра+" КАК Т"
		;
	КонецЕсли;
	
	Текст = Текст + "
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|";
	
	Возврат Текст;

КонецФункции

Функция СтруктураТипаКолонкиДляЗапроса(МассивТиповКолонки)
	
	Перем Результат;
	
	Результат = Новый Структура;
	Результат.Вставить("ЗначениеПоУмолчанию", "НЕОПРЕДЕЛЕНО");
	Результат.Вставить("ИмяДляПриведенияТипов", "");
	
	//Если колонка имеет единственный тип, либо 2 типа, один из которых Null, то в запросе выборки во временную таблицу будем приводить к этому типу, 
	//чтобы избежать ошибок открытия конструктора запросов, если дальше где-то идет выбор "через точку"
	ЕдинственныйТип = Неопределено;
	Если МассивТиповКолонки.Количество() = 1 Тогда
		ЕдинственныйТип = МассивТиповКолонки[0];
	
	ИначеЕсли МассивТиповКолонки.Количество() = 2 Тогда
		Если МассивТиповКолонки[0] = Тип("Null") Тогда
			ЕдинственныйТип = МассивТиповКолонки[1];
		
		ИначеЕсли МассивТиповКолонки[1] = Тип("Null") Тогда
			ЕдинственныйТип = МассивТиповКолонки[0];
		
		КонецЕсли;
	КонецЕсли;
	
	Если ЕдинственныйТип <> Неопределено Тогда
		
		Если ЕдинственныйТип = Тип("Число") Тогда
			Результат.ЗначениеПоУмолчанию = "0";
			
		ИначеЕсли ЕдинственныйТип = Тип("Строка") Тогда
			Результат.ЗначениеПоУмолчанию = """""";
			
		ИначеЕсли ЕдинственныйТип = Тип("Дата") Тогда
			Результат.ЗначениеПоУмолчанию = "ДАТАВРЕМЯ(1,1,1)";
			
		ИначеЕсли ЕдинственныйТип = Тип("Булево") Тогда
			Результат.ЗначениеПоУмолчанию = "ЛОЖЬ";
			
		ИначеЕсли ЕдинственныйТип = Тип("ВидДвиженияНакопления") Тогда
			Результат.ЗначениеПоУмолчанию = "ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)";
			
		Иначе
			ИмяТипаXML = XMLТип(ЕдинственныйТип);
			Если СтрНайти(ИмяТипаXML, "Ref.") > 0 Тогда
				ПустаяСсылка = Новый(ЕдинственныйТип);
				ПолноеИмяМетаданного = ПустаяСсылка.Метаданные().ПолноеИмя();
				Если ЗначениеЗаполнено(ПолноеИмяМетаданного) Тогда
					Результат.ЗначениеПоУмолчанию = "ЗНАЧЕНИЕ("+ПолноеИмяМетаданного+".ПустаяСсылка)";
					Результат.ИмяДляПриведенияТипов = ПолноеИмяМетаданного;
				КонецЕсли;
			КонецЕсли;
		
		КонецЕсли;
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

Как это использовать?

Просто скопируйте эти функции и процедуры в общий модуль с флажком "Серверный" (или в общий модуль расширения, если основная конфигурация на полной поддержке). Пусть общий модуль называется, например "Отладка". Затем запускаем отладку интересующего запроса, останавливаем отладку на строке с Запрос.Выполнить(), нажимаем Shift+F9 и печатаем Отладка.СохранитьЗапрос(Запрос, "\\Host\Share"). Здесь Отладка - это имя общего модуля, Запрос - имя переменной типа "Запрос", \\Host\Share - имя сетевого каталога, куда будет сохранен запрос (этот каталог должен быть доступен для записи пользователем, под которым запущен сервер 1С Предприятие).

Запрос со всеми параметрами будет сохранен в файл \\Host\Share\Запрос_{ТекущаяДатаИВремя}.q1c. При открытии файла *.q1c в консоли запросов запрос и все параметры будут восстановлены. 

Временные таблицы

Если у менеджера временных таблиц запроса есть временные таблицы, они будут сохранены как параметры типа ТаблицаЗначений с именем временной таблицы. Также к началу текста запроса при сохранении будет добавлен текст для создания временных таблиц из параметров типа ТаблицаЗначений. Таким образом открыв сохраненный запрос мы можем сразу выполнить его, он уже будет настроен таким же образом, каким он был настроен в момент выполнения отладки.

Тестовое окружение

Функции проверялись на платформе 8.3.10.2667.

20

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. Evg-Lylyk 2677 13.05.19 12:59 Сейчас в теме
2. Serge R 110 13.05.19 15:50 Сейчас в теме
Я знаю о существовании этой и подобных ей консолей запросов. Моя статья о том, как можно улучшить удобство использования ИТС-ной консоли запросов.
Созинов; +1 Ответить
3. yk1979 21.05.19 13:44 Сейчас в теме
Работает, автору спасибо!
4. Xershi 711 21.05.19 14:03 Сейчас в теме
А в тонком клиенте это будет работать?
5. Serge R 110 21.05.19 19:28 Сейчас в теме
(4) Да, в тонком клиенте работает
Оставьте свое сообщение

См. также

Полезняшки по СКД и построителям. Просто код 36

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Универсальные функции

Полезные процедуры и функции для работы с построителями и СКД. Просто исходник.

10.10.2019    2020    Yashazz    31       

Полезные процедуры и функции для программиста 107

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    5533    HostHost    21       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    7978    ids79    14       

Добавление возможности подключения внешних отчетов и обработок к объектам конфигурации при помощи расширения 10

Статья Программист Нет файла v8::УФ ERP2 Бесплатно (free) Универсальные функции

Часто приходится сталкиваться с тем, что необходимо внести изменения в типовую конфигурацию, но очень не хочется снимать её с поддержки. Для этого в 1С существует ряд инструментов. Эта короткая статья посвящена тому, как подучить возможность подключения внешних отчетов к объекту конфигурации при помощи расширения на примере 1С:ERP Управление предприятием 2 (проверено на 1С:ERP Управление предприятием 2 (2.4.6.230)).

15.04.2019    1980    user995537    0       

Иерархия справочника Сверху Вниз. Получаем произвольное количество родителей "верхнего" уровня 7

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Иерархия справочника Сверху Вниз. Функция для получения произвольного количества родителей "верхнего" уровня. На примере справочника "Номенклатура".

28.03.2019    1985    obsfromekb    11       

Доработка проведения типовых документов в УТ 11.4, КА 2.4, ЕРП 2.4 101

Статья Программист Нет файла v8 v8::УФ ERP2 УТ11 КА2 Россия УУ Бесплатно (free) Практика программирования Универсальные функции Разработка

Различные варианты корректировки типовых механизмов проведения документов, без корректировки основной конфигурации. Использование расширений, подписок на событие и механизма локализации типовых документов.

22.03.2019    8651    ids79    14       

Добавление отчетов в типовые конфигурации 1С 200

Статья Программист Нет файла v8::УФ v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем)

Описание различных способов добавления общих и контекстных отчетов в конфигурации 1С, построенные на базе БСП. Основные моменты и нюансы.

07.03.2019    22900    ids79    32       

Расширение конструктора мобильного рабочего места для варианта "клиент 1С+RDP" (для любых wi-fi терминалов). Экосистема решений Simple WMS 20

Статья Программист Бизнес-аналитик Руководитель проекта Нет файла v8::УФ УУ Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ Бесплатно (free) Инструментарий разработчика Сканер штрих-кода Терминал сбора данных Универсальные функции Мобильная разработка

Развитие проекта «Конструктор мобильного клиента на Android» https://infostart.ru/public/976636/ для устройств не на Андроиде (работающих в режиме RDP). В отличие от варианта Android работа на терминалах происходит в режиме 1С:Предприятие через RDP а конфигурации мобильных клиентов полностью совместимы для обоих версий. Т.е. конфигурация единая, создается один раз и ее может читать как Android -устройство, так и 1С-клиент на RDP без необходимости какой либо переделки.

05.02.2019    5803    informa1555    0       

Работа со строками: от простого к сложному 25

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Простые примеры работы со строками, в конце более читаемый разбор сложных текстов.

14.01.2019    7366    Evg-Lylyk    17       

Нумерация колонок субконто при выгрузке набора записей регистра бухгалтерии в таблицу значений 6

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Решение проблемы несовпадения номеров колонок с номерами субконто на счете при выгрузке в таблицу значений.

14.01.2019    2256    The Ded    3       

Универсальные функции ЗУП 3.1 / ЗКГУ 3.1, которые помогут в разработке 462

Статья Программист Нет файла v8 v8::СПР ЗКГУ3.0 ЗУП3.x БУ Зарплата Управление персоналом (HRM) Бесплатно (free) Универсальные функции

В статье размещен список стандартных процедур и функций с примерами, которые могут помочь при разработке (доработке) конфигураций Зарплата и управление персоналом ред. 3.1 и Зарплата и кадры государственного учреждения 3.1. Иногда бывает довольно сложно правильно получить данные или долго, поэтому лучшим вариантом будет использование стандартных процедур. Буду очень признателен, если Вы поделитесь своим опытом и предложите свои варианты стандартных процедур которые помогают в работе. Или предложите, как дополнить имеющиеся процедуры.

14.11.2018    31350    GeterX    93       

Кадровые данные сотрудников в ЗУП 3.1 в отчетах 38

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Россия Управление персоналом (HRM) Бесплатно (free) Универсальные функции

Параметры используемые для получения данных сотрудников в ЗУП 3.1. Пригодится для разработки отчетов как напоминалка.

07.11.2018    12772    fromlion    12       

Добавление расшифровки в стандартные и добавленные внешние отчеты со стандартной формой отчета на СКД 72

Статья Программист Нет файла v8::УФ v8::СКД ERP2 УТ11 Россия Бесплатно (free) Универсальные функции

Описан способ добавления расшифровки отчета на СКД как встроенного в систему, так и добавленного внешнего отчета.

27.09.2018    6484    bmk74    2       

Функция НайтиФайлы() в каталоге netshare на Linux - обход ошибки работы 6

Статья Программист Нет файла v8 Linux Бесплатно (free) Практика программирования Универсальные функции

Решение проблемы применения функции НайтиФайлы() в каталоге с netshare на Linux-сервере - не работает поиск файлов по указанной маске (шаблону)

19.09.2018    3210    drmaxart    1       

Простой способ программно открыть заполненную форму нового (незаписанного) документа в тонком клиенте 15

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

В этой публикации я поделюсь своим способом открывать программно новый незаписанный документ в тонком клиенте. Для использования этого способа потребуется немного модифицировать конфигурацию. Добавив универсальные процедуру и функцию, можно будет использовать их для любых документов/справочников.

09.06.2018    7340    Serge R    12       

Генерация временного ряда запросом 7

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Универсальные функции

Способ генерации последовательности дат средствами языка запроса 1С.

07.05.2018    5823    dim_zal    6       

Минимализмы 3 350

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35369    ildarovich    44       

Таблица значений в Таблицу HTML - функция с возможностью настройки цвета шапки, заголовков, выравнивания и размера колонок 83

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции

Если вам нужно быстро получить таблицу значений в виде строкового типа 1С в формате HTML, вам поможет эта функция, включена возможность автоматического вывода столбца пункт по порядку.

22.12.2017    18782    rpgshnik    21       

Пример преобразования двоичных данных в строку 26

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Доброго всем времени суток. Хочу поделиться маленьким решением маленькой проблемы. Думаю, будет интересно новичкам. Я не раз встречал на форумах вопрос: как преобразовать двоичные данные в строку? В частности, к примеру, частенько нужно получить хэш файла MD5 в текстовом виде, но как мы знаем 1С возвращает его в виде двоичных данных.

08.12.2017    12331    frkbvfnjh    19       

Функция сохранения картинок из книги Excel в каталог с определением координат на листе 8

Статья Программист Нет файла v8 Бесплатно (free) Загрузка и выгрузка в Excel Универсальные функции

Разбор файла *.xlsx как Web-архива, выгрузка изображений без потери качества, с определением положения изображений.

12.11.2017    7089    user634820_zergemoth    1       

Определяем контекст сеанса 1С программно (Тонкий/Толстый клиенты/HTTP-Сервис/Фоновое задание и т.д.) 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции

Иногда возникает необходимость программно определить контекст сеанса в 1С. Скажем вам надо понять что этот сеанс запущен и используется HTTP-Сервисом и не регламентным заданием или толстым клиентом. Порывшись в интернете я нашел только два способа которые не позволяли отличить регламентное задание от HTTP-Сервиса, стандартная функция ТекущийРежимЗапуска() тоже не позволяет определить запуск HTTP-Сервиса. Но в 1С есть стандартные средства которые позволяют решить эту задачу.

08.11.2017    15304    azubar    9       

Правила округления 5

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Универсальные функции

Округление числовых значений по трём правилам математики

30.10.2017    7648    dakork    4       

#Область ВНЕШНИЕ_ВЫЗОВЫ или MVC в 1С, библиотечность и упрощение интеграции кода 43

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Математика и алгоритмы Универсальные функции

Зачастую почти любой модуль в 1С содержит от одного до несметного множества вызовов других модулей. Как с этим бороться, чтобы было проще куда-то что-то переносить - в этом посте.

12.10.2017    14430    for_sale    58       

Получение даты, зная день недели и его порядок в месяце 10

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Иногда бывает необходимость получить "Первый понедельник месяца" или "Вторую пятницу месяца". Есть несколько способов решения вопроса. Опишу один из них.

12.09.2017    8072    987ww765    10       

Разность дат 21

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Иногда требуется получить разность дат в виде типа: 5 дней 6 месяцев 4 года. Это можно сделать с помощью запроса, получив на выходе сразу 3 нужных числа, без последующих вычислений.

11.08.2017    9705    jun-ko    24       

Простой способ преобразовать UNICODE в строку или в структуру 23

Статья Программист Нет файла v8 Россия Windows Бесплатно (free) Практика программирования Универсальные функции

Первая функция получает Строку, которая содержит строчки вида «Ключ=Значение». Вторая функция получает Структуру.

07.07.2017    7135    dimasts    5       

"Распределение в запросе" или "избавляемся от перебора" 182

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Математика и алгоритмы Универсальные функции

Хороший перебор - это отсутствие перебора. Рассмотрим пример замены полного перебора запросом.

16.12.2016    27739    alexandersh    45       

Пример работы с шаблоном Word через ole (клиент - сервер, тонкий клиент) - установка значений и заполнение таблицы 17

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

В примере показывается заполнение строк готовой таблицы, добавление новой таблицы, объединение ячеек, установка значений в "параметр".

09.11.2016    9977    gortrex    8       

Парсер JSON (Штатные средства 1С 8.3.6) 59

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Хочу поделиться функцией чтения json, реализованной с помощью штатных средств платформы.

29.09.2016    46238    dour-dead    21       

Программное создание графических схем (v.2): API для ГрафическойСхемы 73

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Работа с интерфейсом Универсальные функции

Пример динамического создания графических схем, добавления элементов любых видов. Любые схемы без бизнес-процессов. Программная работа со схемой. Отличие от существующей статьи в том, что здесь используется объектная модель. Исправил и упростил некоторые моменты - результат соответствует схеме, созданной руками. Добавил возможность рисования произвольных форм для существующих фигур.

27.09.2016    16848    serg_infostart    15       

Вычитание рабочих дней от текущей даты 7

Статья Программист Нет файла v8 Россия Бесплатно (free) Практика программирования Универсальные функции

Функция возвращает дату, которая меньше указанной даты на количество рабочих дней по выбранному графику

08.09.2016    9573    semenich_b    7       

Используем механизмы обмена данными БСП для произвольного обмена 147

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции Внешние источники данных БСП (Библиотека стандартных подсистем)

Механизм БСП заточен на обмен XML по правилам обмена. Чтобы использовать его для любого другого обмена, коих в мире немало, требуются доработки. В статье описан вариант, как из положения выйти.

23.08.2016    27613    Патриот    22       

Склонение числа прописью 25

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Склоняет число прописью до 999999 Пример: до склонения "Не позднее 3 (Три) дней", после - "Не позднее 3 (Трех) дней"

18.08.2016    15817    maxvcb    27       

Отборы в отчётах. Нюансы работы компоновщика настроек. 132

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Открытие отчёта с предустановленным отбором, показанным пользователю. Изменение любых настроек в процессе работы отчёта. Взаимосвязи настроек.

15.08.2016    59087    Yashazz    23       

Автоматическое добавление новых реквизитов на форму (УФ) 38

Статья Программист Нет файла v8 v8::УФ Бесплатно (free) Работа с интерфейсом Универсальные функции

Идея такая: Программист добавил реквизит в объект. В комментарии этого реквизита прописал некое спец. слово (можно не матерное). На форму объекта новый реквизит далее попадает автоматом в спец. группу "Дополнительно".

03.08.2016    16162    Патриот    23       

HOWTO: создание и отладка HTTP-сервиса в 1С:Предприятие 123

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) WEB Практика программирования Универсальные функции

Статья о том, как можно быстро создать HTTP-сервис в 1С:Предприятие и как выполнять его отладку.

25.07.2016    39342    serg_infostart    19       

Цикл ввода данных, пример решения 41

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Отказ от модальности создает проблему организации последовательного ввода данных в рамках одной пользовательской операции. Цепочки процедур, обрабатывающих введенные данные и вызывающие следующий диалог - головная боль даже для самостоятельной поддержки или изменения логики ввода, не говоря о том уже, чтобы разбираться в чужом коде. Предлагаемое решение является некой заготовкой и может быть любым образом улучшено.

12.07.2016    11143    botokash    7       

Поиск несериализуемых значений при помещении в хранилище 12

Статья Программист Нет файла v8 Windows Бесплатно (free) Инструментарий разработчика Практика программирования Универсальные функции

В статье разобран пример, как найти несериализуемые значения в случае помещения в хранилище коллекций, содержащих вложенные элементы. В качестве хранилищ рассмотрены временное хранилище значений и переменные типа ХранилищеЗначения.

02.03.2016    20009    balanton    2       

Универсальные функции с примерами использования 241

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

14 универсальных функций, с примерами использования - для обычного и управляемого интерфейса

26.02.2016    35327    unichkin    36       

Преобразование числа в строку в запросе 1С 8.x 21

Статья Программист Нет файла v8 1cv8.cf Windows Бесплатно (free) Универсальные функции

В запросах 1С предприятие 8.x есть ограничение: нельзя преобразовывать число в строку.

23.02.2016    32875    lastcontra    19       

Изменения параметра или отбора типа Дата в форме отчета 6

Статья Программист Нет файла v8 Бесплатно (free) Универсальные функции

Иногда в отчетах стандартных периодов (Начало текущего месяца, начало следующего месяца и т.д.) недостаточно. Приходится ставить произвольную дату и устанавливать периоды вручную (конец месяца, конец недели и т.д.). В публикации выложен листинг кода, который должен ускорить установку параметров и отборов с типом Дата.

08.02.2016    9772    dj_serega    3       

Использование классов .Net в 1С для новичков 147

Статья Программист Нет файла v7.7 v8 Windows Бесплатно (free) Практика программирования Разработка внешних компонент Универсальные функции

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    62624    Serginio    104       

Быстрое визуальное сравнение двух таблиц значений 18

Статья Программист Нет файла v8 Windows Бесплатно (free) Универсальные функции

Предлагаю простой способ сравнить две таблицы значений.

13.11.2015    11866    Mi4man    14       

Перебор всех строк дерева значений в глубину 2

Статья Программист Нет файла v8 Windows Бесплатно (free) Универсальные функции

Процедура и функция перебора всех строк дерева значений в глубину.

11.11.2015    11386    kosmo0    6